mirror of
https://github.com/Unidata/netcdf-c.git
synced 2024-11-27 07:30:33 +08:00
3db4f013bf
Specific changes:
1. Add dap4 code: libdap4 and dap4_test.
Note that until the d4ts server problem is solved, dap4 is turned off.
2. Modify various files to support dap4 flags:
configure.ac, Makefile.am, CMakeLists.txt, etc.
3. Add nc_test/test_common.sh. This centralizes
the handling of the locations of various
things in the build tree: e.g. where is
ncgen.exe located. See nc_test/test_common.sh
for details.
4. Modify .sh files to use test_common.sh
5. Obsolete separate oc2 by moving it to be part of
netcdf-c. This means replacing code with netcdf-c
equivalents.
5. Add --with-testserver to configure.ac to allow
override of the servers to be used for --enable-dap-remote-tests.
6. There were multiple versions of nctypealignment code. Try to
centralize in libdispatch/doffset.c and include/ncoffsets.h
7. Add a unit test for the ncuri code because of its complexity.
8. Move the findserver code out of libdispatch and into
a separate, self contained program in ncdap_test and dap4_test.
9. Move the dispatch header files (nc{3,4}dispatch.h) to
.../include because they are now shared by modules.
10. Revamp the handling of TOPSRCDIR and TOPBUILDDIR for shell scripts.
11. Make use of MREMAP if available
12. Misc. minor changes e.g.
- #include <config.h> -> #include "config.h"
- Add some no-install headers to /include
- extern -> EXTERNL and vice versa as needed
- misc header cleanup
- clean up checking for misc. unix vs microsoft functions
13. Change copyright decls in some files to point to LICENSE file.
14. Add notes to RELEASENOTES.md
139 lines
3.8 KiB
CMake
139 lines
3.8 KiB
CMake
|
|
SET(liblib_LIBS dispatch netcdf3)
|
|
|
|
#####
|
|
# Add target objects/modules based on options.
|
|
#####
|
|
|
|
IF(USE_HDF5 OR USE_NETCDF4)
|
|
SET(liblib_LIBS ${liblib_LIBS} netcdf4)
|
|
ENDIF()
|
|
|
|
IF(USE_PNETCDF)
|
|
SET(liblib_LIBS ${liblib_LIBS} netcdfp)
|
|
ENDIF()
|
|
|
|
IF(ENABLE_DAP2)
|
|
SET(liblib_LIBS ${liblib_LIBS} oc2 dap2)
|
|
ENDIF()
|
|
|
|
IF(ENABLE_DAP4)
|
|
SET(liblib_LIBS ${liblib_LIBS} dap4)
|
|
ENDIF()
|
|
|
|
FOREACH(LIBS ${liblib_LIBS})
|
|
SET(LARGS ${LARGS} $<TARGET_OBJECTS:${LIBS}>)
|
|
ENDFOREACH()
|
|
|
|
ADD_LIBRARY(netcdf nc_initialize.c ${LARGS} )
|
|
|
|
IF(MOD_NETCDF_NAME)
|
|
SET_TARGET_PROPERTIES(netcdf PROPERTIES LIBRARY_OUTPUT_NAME ${NETCDF_LIB_NAME})
|
|
SET_TARGET_PROPERTIES(netcdf PROPERTIES ARCHIVE_OUTPUT_NAME ${NETCDF_LIB_NAME})
|
|
SET_TARGET_PROPERTIES(netcdf PROPERTIES RUNTIME_OUTPUT_NAME ${NETCDF_LIB_NAME})
|
|
ENDIF()
|
|
|
|
#####
|
|
# Add dependencies required for linking.
|
|
#####
|
|
|
|
SET(TLL_LIBS "")
|
|
|
|
SET(TLL_LIBS ${TLL_LIBS} ${HAVE_LIBM} ${ZLIB_LIBRARY})
|
|
|
|
# Add extra dependencies specified via NC_EXTRA_DEPS
|
|
SET(TLL_LIBS ${TLL_LIBS} ${EXTRA_DEPS})
|
|
|
|
IF(HAVE_LIBDL)
|
|
SET(TLL_LIBS ${LIBDL} ${TLL_LIBS})
|
|
ENDIF()
|
|
|
|
IF(USE_HDF5 OR USE_NETCDF4)
|
|
IF(NOT MSVC)
|
|
# Some version of cmake define HDF5_hdf5_LIBRARY instead of
|
|
# HDF5_LIBRARY. Same with HDF5_HL_LIBRARIES
|
|
IF(HDF5_hdf5_LIBRARY AND NOT HDF5_C_LIBRARIES)
|
|
SET(HDF5_C_LIBRARIES ${HDF5_hdf5_LIBRARY})
|
|
ENDIF()
|
|
IF(HDF5_hdf5_hl_LIBRARY AND NOT HDF5_HL_LIBRARIES)
|
|
SET(HDF5_HL_LIBRARIES ${HDF5_hdf5_hl_LIBRARY})
|
|
ENDIF()
|
|
# The order of the libraries is important here for static
|
|
# builds:
|
|
# Make sure that HDF5_C_LIBRARY appears *after*
|
|
# HDF5_HL_LIBRARY.
|
|
SET(TLL_LIBS ${HDF5_HL_LIBRARIES} ${HDF5_C_LIBRARIES} ${TLL_LIBS} ${SZIP_LIBRARY})
|
|
ELSE() # Windows CMake defines HDF5_LIBRARIES.
|
|
SET(TLL_LIBS ${HDF5_LIBRARIES} ${TLL_LIBS} ${SZIP_LIBRARY})
|
|
ENDIF()
|
|
ENDIF()
|
|
|
|
IF(USE_DAP)
|
|
SET(TLL_LIBS ${TLL_LIBS} ${CURL_LIBRARY})
|
|
ENDIF()
|
|
|
|
IF(USE_HDF4)
|
|
SET(TLL_LIBS ${HDF4_MFHDF_LIB} ${HDF4_DF_LIB} ${TLL_LIBS})
|
|
ENDIF()
|
|
|
|
IF(ENABLE_PNETCDF AND PNETCDF)
|
|
SET(TLL_LIBS ${TLL_LIBS} ${PNETCDF})
|
|
ENDIF()
|
|
|
|
IF(TLL_LIBS)
|
|
LIST(REMOVE_DUPLICATES TLL_LIBS)
|
|
ENDIF()
|
|
|
|
TARGET_LINK_LIBRARIES(netcdf ${TLL_LIBS})
|
|
SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} ${TLL_LIBS})
|
|
IF(MSVC)
|
|
SET_TARGET_PROPERTIES(netcdf PROPERTIES
|
|
LINK_FLAGS_DEBUG " /NODEFAULTLIB:MSVCRT"
|
|
)
|
|
ENDIF()
|
|
|
|
IF(NOT MSVC)
|
|
IF(BUILD_SHARED_LIBS)
|
|
SET_TARGET_PROPERTIES(netcdf PROPERTIES LINK_FLAGS -shared)
|
|
ENDIF()
|
|
ENDIF()
|
|
|
|
IF(ENABLE_SHARED_LIBRARY_VERSION)
|
|
SET_TARGET_PROPERTIES(netcdf PROPERTIES
|
|
VERSION ${netCDF_LIB_VERSION}
|
|
SOVERSION ${netCDF_SO_VERSION}
|
|
)
|
|
ENDIF(ENABLE_SHARED_LIBRARY_VERSION)
|
|
|
|
###
|
|
# The INCLUDES directive was introduced in 2.8.12.
|
|
# However, 2.8.11 is still the default on some
|
|
# popular linux distributions. See
|
|
# https://github.com/Unidata/netcdf-c/issues/135
|
|
# for more information.
|
|
###
|
|
IF(${CMAKE_VERSION} VERSION_LESS 2.8.12)
|
|
INSTALL(
|
|
TARGETS netcdf EXPORT netCDFTargets
|
|
LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries
|
|
ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries
|
|
RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT libraries
|
|
PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
|
|
)
|
|
ELSE()
|
|
INSTALL(
|
|
TARGETS netcdf EXPORT netCDFTargets
|
|
LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries
|
|
ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries
|
|
RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT libraries
|
|
INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
|
|
)
|
|
ENDIF()
|
|
|
|
SET(ALL_TLL_LIBS ${TLL_LIBS} PARENT_SCOPE)
|
|
SET(NC_LIBS ${NC_LIBS} PARENT_SCOPE)
|
|
|
|
FILE(GLOB CUR_EXTRA_DIST RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/*.h ${CMAKE_CURRENT_SOURCE_DIR}/*.c)
|
|
SET(CUR_EXTRA_DIST ${CUR_EXTRA_DIST} CMakeLists.txt Makefile.am)
|
|
ADD_EXTRA_DIST("${CUR_EXTRA_DIST}")
|