mirror of
git://git.savannah.gnu.org/libtool.git
synced 2024-11-27 06:09:57 +08:00
a69688b769
then tweak the results by hand: * m4/libtool.m4 (AC_PROG_LD): In common with all the other AC_PROG_ macros, AC_SUBST the discovered LD. (AC_PROG_NM): Similarly for NM. (LT_AC_PROG_SED): Similarly for SED. * configure.ac: No need to SUBST NM and LD manually any more. (AC_PREREQ): Conservatively downgrade from 2.59 to 2.54. * tests/cdemo/configure.ac, tests/demo/configure.ac, tests/depdemo/configure.ac, tests/f77demo/configure.ac, tests/mdemo/configure.ac, tests/mdemo2/configure.ac, tests/pdemo/configure.ac, tests/tagdemo/configure.ac: Ditto. * m4/libtool.m4 (AM_PROG_LIBTOOL, AM_ENABLE_SHARED, AM_ENABLE_STATIC, AM_DISABLE_SHARED, AM_DISABLE_STATIC, AM_PROG_LD, AM_PROG_NM): AU_DEFUN these macros so autoupdate can use the newer definitions.
145 lines
3.8 KiB
Plaintext
145 lines
3.8 KiB
Plaintext
## Process this file with autoconf to create configure. -*- autoconf -*-
|
|
# Copyright 2001 Free Software Foundation, Inc.
|
|
#
|
|
# This program is free software; you can redistribute it and/or modify
|
|
# it under the terms of the GNU General Public License as published by
|
|
# the Free Software Foundation; either version 2 of the License, or
|
|
# (at your option) any later version.
|
|
#
|
|
# This program is distributed in the hope that it will be useful,
|
|
# but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
# GNU General Public License for more details.
|
|
#
|
|
# You should have received a copy of the GNU General Public License
|
|
# along with this program; if not, write to the Free Software
|
|
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
|
|
# 02111-1307 USA
|
|
|
|
|
|
## FIXME: Is this really new enough? ##
|
|
AC_PREREQ(2.54)
|
|
|
|
|
|
|
|
## ------------------------ ##
|
|
## Autoconf initialisation. ##
|
|
## ------------------------ ##
|
|
AC_INIT([libtool], [1.5a], [bug-libtool@gnu.org])
|
|
AC_CONFIG_SRCDIR([ltmain.in])
|
|
AC_CONFIG_AUX_DIR([config])
|
|
|
|
|
|
## ------------------------ ##
|
|
## Autotest initialisation. ##
|
|
## ------------------------ ##
|
|
|
|
dnl AC_CONFIG_TESTDIR([tests])
|
|
dnl AC_CONFIG_FILES([tests/atlocal])
|
|
|
|
|
|
## ---------------------------------------- ##
|
|
## Display a configure time version banner. ##
|
|
## ---------------------------------------- ##
|
|
|
|
# This is a sanity check so we can see which version is used in bug reports.
|
|
# It is assumed that we only want to see the date extension for cvs libtool
|
|
# versions (i.e. "odd" letters) and not actual alpha releases.
|
|
TIMESTAMP=
|
|
case AC_PACKAGE_VERSION in
|
|
[*[acegikmoqsuwy])]
|
|
TIMESTAMP=`${CONFIG_SHELL} ${ac_aux_dir}/mkstamp < ${srcdir}/ChangeLog`
|
|
AS_BOX([Configuring AC_PACKAGE_TARNAME AC_PACKAGE_VERSION$TIMESTAMP])
|
|
echo
|
|
;;
|
|
esac
|
|
AC_SUBST([TIMESTAMP])
|
|
|
|
|
|
|
|
## ------------------------ ##
|
|
## Automake Initialisation. ##
|
|
## ------------------------ ##
|
|
AM_INIT_AUTOMAKE
|
|
|
|
|
|
## ------------------------------- ##
|
|
## Libtool specific configuration. ##
|
|
## ------------------------------- ##
|
|
pkgdatadir='${datadir}'"/${PACKAGE}"
|
|
AC_SUBST([pkgdatadir]) # automake does not need this, but libtoolize does
|
|
|
|
aclocaldir='${datadir}/aclocal'
|
|
AC_SUBST([aclocaldir])
|
|
|
|
AC_ARG_ENABLE(ltdl-install,
|
|
[AS_HELP_STRING([--disable-ltdl-install], [do not install libltdl])])
|
|
if test x"${enable_ltdl_install+set}" != xset; then
|
|
enable_ltdl_install=yes
|
|
ac_configure_args="$ac_configure_args --enable-ltdl-install"
|
|
fi
|
|
AC_CONFIG_SUBDIRS([libltdl])
|
|
|
|
# all subdirectories that are configured on demand, but that must be
|
|
# included in the distribution
|
|
CONF_SUBDIRS="tests/cdemo tests/demo tests/depdemo tests/f77demo tests/mdemo tests/mdemo2 tests/pdemo tests/tagdemo"
|
|
AC_SUBST([CONF_SUBDIRS])
|
|
|
|
DIST_MAKEFILE_LIST=
|
|
for dir in $CONF_SUBDIRS; do
|
|
DIST_MAKEFILE_LIST="$DIST_MAKEFILE_LIST$dir/Makefile "
|
|
done
|
|
AC_SUBST([DIST_MAKEFILE_LIST])
|
|
|
|
|
|
|
|
## ---------------- ##
|
|
## compiler checks. ##
|
|
## ---------------- ##
|
|
|
|
# Use the specified CC and LD
|
|
AC_PROG_CC
|
|
AC_EXEEXT
|
|
AC_PROG_LD
|
|
AC_PROG_NM
|
|
AC_PROG_LN_S
|
|
|
|
pushdef([AC_MSG_ERROR], [CXX=no])
|
|
AC_PROG_CXX
|
|
popdef([AC_MSG_ERROR])
|
|
AM_CONDITIONAL(HAVE_CXX, [test "x$CXX" != xno])
|
|
|
|
pushdef([AC_MSG_ERROR], [F77=no])
|
|
AC_PROG_F77
|
|
popdef([AC_MSG_ERROR])
|
|
if test -z "$F77"; then
|
|
F77="no"
|
|
fi
|
|
AM_CONDITIONAL(HAVE_F77, [test "x$F77" != xno])
|
|
|
|
LT_AC_PROG_GCJ
|
|
AM_CONDITIONAL(HAVE_GCJ, [test "x$GCJ" != xno])
|
|
|
|
LT_AC_PROG_RC
|
|
AM_CONDITIONAL(HAVE_RC, [test "x$RC" != xno])
|
|
|
|
|
|
|
|
## ----------------------- ##
|
|
## Libtool initialisation. ##
|
|
## ----------------------- ##
|
|
AC_CONFIG_FILES([config/ltmain.sh:./ltmain.in])
|
|
AC_CONFIG_COMMANDS([libltdl/ltmain.sh],
|
|
[cp -f config/ltmain.sh libltdl/ltmain.sh])
|
|
AC_LIBTOOL_DLOPEN
|
|
AC_LIBTOOL_WIN32_DLL
|
|
AC_PROG_LIBTOOL
|
|
|
|
|
|
|
|
## -------- ##
|
|
## Outputs. ##
|
|
## -------- ##
|
|
AC_CONFIG_FILES([Makefile doc/Makefile tests/Makefile])
|
|
AC_OUTPUT
|