mirror of
git://git.savannah.gnu.org/libtool.git
synced 2024-12-21 06:59:11 +08:00
9f92691646
the ltcf-*.sh and ltconfig.in files from multi-language-branch: * libtool.m4: More refactoring and reformatting. (_LT_AC_LANG_GCJ_CONFIG): Merged ltcf-gcj.sh from multi-language-branch. (_LT_AC_LANG_CXX_CONFIG): Merged ltcf-cxx.sh from multi-language-branch. * configure.in (AC_PROG_CXX, LT_AC_PROG_GCJ): Compiler checks must be done before AC_PROG_LIBTOOL which appends tags based on their results.
92 lines
2.5 KiB
Plaintext
92 lines
2.5 KiB
Plaintext
## Process this file with autoconf to create configure.
|
|
|
|
AC_INIT(ltmain.in)
|
|
|
|
AM_INIT_AUTOMAKE(libtool, 1.4)
|
|
|
|
# This is a sanity check so we can see which version is used in bug reports.
|
|
# It is assumed that we only want to see the date extension for cvs libtool
|
|
# versions (i.e. "odd" letters) and not actual alpha releases.
|
|
TIMESTAMP=
|
|
case "$VERSION" in
|
|
[*[acegikmoqsuwy])]
|
|
TIMESTAMP=`${CONFIG_SHELL} ${srcdir}/mkstamp < ${srcdir}/ChangeLog`
|
|
banner="Configuring $PACKAGE $VERSION$TIMESTAMP"
|
|
dashes=`echo "$banner" | sed 's/./-/g'`
|
|
|
|
# Display an obvious version banner
|
|
echo
|
|
echo $dashes
|
|
echo "$banner"
|
|
echo $dashes
|
|
echo
|
|
;;
|
|
esac
|
|
AC_SUBST(TIMESTAMP)
|
|
|
|
pkgdatadir='${datadir}'"/${PACKAGE}"
|
|
AC_SUBST(pkgdatadir) # automake does not need this, but libtoolize does
|
|
aclocaldir='${datadir}/aclocal'
|
|
AC_SUBST(aclocaldir)
|
|
|
|
# Use the specified CC and LD
|
|
AC_PROG_CC
|
|
|
|
# Autoconf-2.13 AC_REQUIRE resolution confuses the ordering for the
|
|
# preprocessor test if left to figure this out for itself -- by forcing that
|
|
# checks here, AC_REQUIRE doesn't need to add it. When we upgrade to
|
|
# Autoconf-2.50, this can be removed.
|
|
AC_PROG_CPP
|
|
|
|
AM_PROG_LD
|
|
AC_SUBST(LD)
|
|
AM_PROG_NM
|
|
AC_SUBST(NM)
|
|
AC_PROG_LN_S
|
|
|
|
pushdef([AC_MSG_ERROR], [CXX=no])
|
|
AC_PROG_CXX
|
|
popdef([AC_MSG_ERROR])
|
|
AM_CONDITIONAL(HAVE_CXX, [test "x$CXX" != xno])
|
|
|
|
LT_AC_PROG_GCJ
|
|
AM_CONDITIONAL(HAVE_GCJ, [test "x$GCJ" != xno])
|
|
|
|
# Declare win32 dll support
|
|
AC_LIBTOOL_WIN32_DLL
|
|
|
|
# Autoconf-2.13 AC_REQUIRE resolution confuses the ordering for the cygwin
|
|
# and mingw tests if left to figure this out for itself -- by forcing those
|
|
# checks here, AC_REQUIRE doesn't need to add them. When we upgrade to
|
|
# Autoconf-2.50, this can be removed.
|
|
AC_EXEEXT
|
|
AC_OBJEXT
|
|
|
|
# Check for dlopen support
|
|
AC_LIBTOOL_DLOPEN
|
|
AC_PROG_LIBTOOL
|
|
|
|
AC_ARG_ENABLE(ltdl-install,
|
|
[ --disable-ltdl-install do not install libltdl])
|
|
if test x"${enable_ltdl_install+set}" != xset; then
|
|
enable_ltdl_install=yes
|
|
ac_configure_args="$ac_configure_args --enable-ltdl-install"
|
|
fi
|
|
AC_CONFIG_SUBDIRS(libltdl)
|
|
|
|
# all subdirectories that are configured on demand, but that must be
|
|
# included in the distribution
|
|
CONF_SUBDIRS="cdemo pdemo demo depdemo mdemo tagdemo"
|
|
AC_SUBST(CONF_SUBDIRS)
|
|
|
|
ACINCLUDE_M4_LIST="${srcdir}/acinclude.m4"
|
|
DIST_MAKEFILE_LIST=
|
|
for dir in $CONF_SUBDIRS; do
|
|
ACINCLUDE_M4_LIST="$ACINCLUDE_M4_LIST ${srcdir}/$dir/acinclude.m4"
|
|
DIST_MAKEFILE_LIST="$DIST_MAKEFILE_LIST$dir/Makefile "
|
|
done
|
|
AC_SUBST(ACINCLUDE_M4_LIST)
|
|
AC_SUBST(DIST_MAKEFILE_LIST)
|
|
|
|
AC_OUTPUT([Makefile doc/Makefile tests/Makefile])
|