mirror of
git://git.savannah.gnu.org/libtool.git
synced 2025-02-23 15:19:27 +08:00
73263db76b
tests/defs, and move the various demo directories out of $top_srcdir, and into tests too. The refactoring showed up a number of inconsistencies and latent bugs, as well as fixing (I think!!) the long-standing annoyance with some of the tests giving spurious failures intermittently. While I was here, emacs kindly removed a lot of bogus whitespace and added copyright notices for us: * cdemo, demo, depdemo, f77demo, mdemo, mdemo2, pdemo, tagdemo: Moved from here... * tests/cdemo, tests/demo, tests/depdemo, tests/f77demo, tests/mdemo, tests/mdemo2, tests/pdemo, tests/tagdemo: ...to here. * tests/defs: Factor much common functionality from the test scripts into shell functions. Added a copyright notice. * tests/assign.test, tests/cdemo-conf.test, tests/cdemo-exec.test, tests/cdemo-make.test, tests/cdemo-shared.test, tests/cdemo-static.test, tests/demo-conf.test, tests/demo-deplibs.test, tests/demo-exec.test, tests/demo-inst.test, tests/demo-make.test, tests/demo-nofast.test, tests/demo-nopic.test, tests/demo-pic.test, tests/demo-shared.test, tests/demo-static.test, tests/demo-unst.test, tests/depdemo-conf.test, tests/depdemo-exec.test, tests/depdemo-inst.test, tests/depdemo-make.test, tests/depdemo-nofast.test, tests/depdemo-shared.test, tests/depdemo-static.test, tests/depdemo-unst.test, tests/f77demo-conf.test, tests/f77demo-exec.test, tests/f77demo-make.test, tests/f77demo-shared.test, tests/f77demo-static.test, tests/link-2.test, tests/link.test, tests/mdemo-conf.test, tests/mdemo-exec.test, tests/mdemo-inst.test, tests/mdemo-make.test, tests/mdemo-shared.test, tests/mdemo-static.test, tests/mdemo-unst.test, tests/mdemo2-conf.test, tests/mdemo2-exec.test, tests/mdemo2-make.test, tests/nomode.test, tests/pdemo-conf.test, tests/pdemo-exec.test, tests/pdemo-inst.test, tests/pdemo-make.test, tests/pdemo-unst.test, tests/quote.test, tests/sh.test, tests/suffix.test, tests/tagdemo-conf.test, tests/tagdemo-exec.test, tests/tagdemo-make.test, tests/tagdemo-shared.test, tests/tagdemo-static.test: Refactored to use new functions in tests/defs. Added a copyright notice. * tests/hardcode.test, noinst-link.test, tests/relink.test, tests/relink.test, tests/mdryrun.test: Ditto. Moved from here... * tests/demo-hardcode.test, demo-noinst-link.test, tests/demo-relink.test, tests/depdemo-relink.test, tests/mdemo-dryrun.test: ...to here respectively. * Makefile.am: Added a copyright notice. * tests/sh.test: Check libtoolize.in for non-portabilities too. * libtoolize.in: Fix non-portabilities found by tests/sh.test.
139 lines
3.6 KiB
Plaintext
139 lines
3.6 KiB
Plaintext
## Process this file with autoconf to create configure. -*- autoconf -*-
|
|
# Copyright 2001 Free Software Foundation, Inc.
|
|
#
|
|
# This program is free software; you can redistribute it and/or modify
|
|
# it under the terms of the GNU General Public License as published by
|
|
# the Free Software Foundation; either version 2 of the License, or
|
|
# (at your option) any later version.
|
|
#
|
|
# This program is distributed in the hope that it will be useful,
|
|
# but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
# GNU General Public License for more details.
|
|
#
|
|
# You should have received a copy of the GNU General Public License
|
|
# along with this program; if not, write to the Free Software
|
|
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
|
|
# 02111-1307 USA
|
|
|
|
|
|
## FIXME: Is this really new enough? ##
|
|
AC_PREREQ(2.50)
|
|
|
|
|
|
|
|
## ------------------------ ##
|
|
## Autoconf initialisation. ##
|
|
## ------------------------ ##
|
|
AC_INIT([libtool], [1.5a], [bug-libtool@gnu.org])
|
|
AC_CONFIG_SRCDIR([ltmain.in])
|
|
AC_CONFIG_AUX_DIR([config])
|
|
|
|
AC_CONFIG_TESTDIR([tests])
|
|
AC_CONFIG_FILES([tests/atlocal])
|
|
|
|
|
|
## ---------------------------------------- ##
|
|
## Display a configure time version banner. ##
|
|
## ---------------------------------------- ##
|
|
|
|
# This is a sanity check so we can see which version is used in bug reports.
|
|
# It is assumed that we only want to see the date extension for cvs libtool
|
|
# versions (i.e. "odd" letters) and not actual alpha releases.
|
|
TIMESTAMP=
|
|
case AC_PACKAGE_VERSION in
|
|
[*[acegikmoqsuwy])]
|
|
TIMESTAMP=`${CONFIG_SHELL} ${ac_aux_dir}/mkstamp < ${srcdir}/ChangeLog`
|
|
AS_BOX([Configuring AC_PACKAGE_TARNAME AC_PACKAGE_VERSION$TIMESTAMP])
|
|
echo
|
|
;;
|
|
esac
|
|
AC_SUBST([TIMESTAMP])
|
|
|
|
|
|
|
|
## ------------------------ ##
|
|
## Automake Initialisation. ##
|
|
## ------------------------ ##
|
|
AM_INIT_AUTOMAKE(AC_PACKAGE_TARNAME, AC_PACKAGE_VERSION)
|
|
|
|
|
|
## ------------------------------- ##
|
|
## Libtool specific configuration. ##
|
|
## ------------------------------- ##
|
|
pkgdatadir='${datadir}'"/${PACKAGE}"
|
|
AC_SUBST([pkgdatadir]) # automake does not need this, but libtoolize does
|
|
|
|
aclocaldir='${datadir}/aclocal'
|
|
AC_SUBST([aclocaldir])
|
|
|
|
AC_ARG_ENABLE(ltdl-install,
|
|
[AC_HELP_STRING([--disable-ltdl-install], [do not install libltdl])])
|
|
if test x"${enable_ltdl_install+set}" != xset; then
|
|
enable_ltdl_install=yes
|
|
ac_configure_args="$ac_configure_args --enable-ltdl-install"
|
|
fi
|
|
AC_CONFIG_SUBDIRS([libltdl])
|
|
|
|
# all subdirectories that are configured on demand, but that must be
|
|
# included in the distribution
|
|
CONF_SUBDIRS="tests/cdemo tests/demo tests/depdemo tests/f77demo tests/mdemo tests/mdemo2 tests/pdemo tests/tagdemo"
|
|
AC_SUBST([CONF_SUBDIRS])
|
|
|
|
DIST_MAKEFILE_LIST=
|
|
for dir in $CONF_SUBDIRS; do
|
|
DIST_MAKEFILE_LIST="$DIST_MAKEFILE_LIST$dir/Makefile "
|
|
done
|
|
AC_SUBST([DIST_MAKEFILE_LIST])
|
|
|
|
|
|
|
|
## ---------------- ##
|
|
## compiler checks. ##
|
|
## ---------------- ##
|
|
|
|
# Use the specified CC and LD
|
|
AC_PROG_CC
|
|
AC_EXEEXT
|
|
AM_PROG_LD
|
|
AC_SUBST(LD)
|
|
AM_PROG_NM
|
|
AC_SUBST(NM)
|
|
AC_PROG_LN_S
|
|
|
|
pushdef([AC_MSG_ERROR], [CXX=no])
|
|
AC_PROG_CXX
|
|
popdef([AC_MSG_ERROR])
|
|
AM_CONDITIONAL(HAVE_CXX, [test "x$CXX" != xno])
|
|
|
|
pushdef([AC_MSG_ERROR], [F77=no])
|
|
AC_PROG_F77
|
|
popdef([AC_MSG_ERROR])
|
|
if test -z "$F77"; then
|
|
F77="no"
|
|
fi
|
|
AM_CONDITIONAL(HAVE_F77, [test "x$F77" != xno])
|
|
|
|
LT_AC_PROG_GCJ
|
|
AM_CONDITIONAL(HAVE_GCJ, [test "x$GCJ" != xno])
|
|
|
|
LT_AC_PROG_RC
|
|
AM_CONDITIONAL(HAVE_RC, [test "x$RC" != xno])
|
|
|
|
|
|
|
|
## ----------------------- ##
|
|
## Libtool initialisation. ##
|
|
## ----------------------- ##
|
|
AC_LIBTOOL_DLOPEN
|
|
AC_LIBTOOL_WIN32_DLL
|
|
AC_PROG_LIBTOOL
|
|
|
|
|
|
|
|
## -------- ##
|
|
## Outputs. ##
|
|
## -------- ##
|
|
AC_CONFIG_FILES([Makefile doc/Makefile tests/Makefile])
|
|
AC_OUTPUT
|