mirror of
git://git.savannah.gnu.org/libtool.git
synced 2024-11-21 01:40:57 +08:00
b544ca3784
* Makefile.am (configure_edit): Rename pkgconfig_files substitution to pkgaux_files, and add pkgaux_install_files and pkgaux_parent_files substitutions for atlocal. (pkgauxdir): Where to install pkgaux_files. (auxfiles): Removed, and replaced by... (pkgaux_parent_files, pkgaux_install_files, pkgaux_data_files): ...these, which separate the files lists more logically for easier installation, and use by libtoolize.m4sh. (uninstall-hook): Adjust. (tests/atlocal): Adjust. * bootstrap.conf (libtool_link_libltdl_subdirs): Adjust. * libtoolize.m4sh (func_install_pkgconfig_files) (func_install_pkgconfig_subproject) (func_install_pkgconfig_parent, func_install_pkgconfig_files) (all_pkgconfig_files): Renamed to... (func_install_pkgaux_files, unc_install_pkgaux_subproject) (func_install_pkgaux_parent, func_install_pkgaux_files) (all_pkgaux_files): ...these, resp. Adjust all callers. (func_massage_pkgconfig_files): Removed. (pkgaux_files): List of all auxiliary scripts substituted from Makefile. Signed-off-by: Gary V. Vaughan <gary@gnu.org>
224 lines
6.7 KiB
Plaintext
224 lines
6.7 KiB
Plaintext
# Process this file with autoconf to create configure. -*- autoconf -*-
|
|
|
|
# Copyright (C) 2001, 2004, 2005, 2008, 2010 Free Software Foundation,
|
|
# Inc.
|
|
# Written by Gary V. Vaughan, 2001
|
|
#
|
|
# This file is part of GNU Libtool.
|
|
#
|
|
# GNU Libtool is free software; you can redistribute it and/or
|
|
# modify it under the terms of the GNU General Public License as
|
|
# published by the Free Software Foundation; either version 2 of
|
|
# the License, or (at your option) any later version.
|
|
#
|
|
# GNU Libtool is distributed in the hope that it will be useful,
|
|
# but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
# GNU General Public License for more details.
|
|
#
|
|
# You should have received a copy of the GNU General Public License
|
|
# along with GNU Libtool; see the file COPYING. If not, a copy
|
|
# can be downloaded from http://www.gnu.org/licenses/gpl.html,
|
|
# or obtained by writing to the Free Software Foundation, Inc.,
|
|
# 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
|
|
####
|
|
|
|
|
|
AC_PREREQ(2.62)dnl Some m4sh scripts use $as_echo
|
|
dnl Oldest automake required for bootstrap is below in AM_INIT_AUTOMAKE.
|
|
|
|
|
|
## ------------------------ ##
|
|
## Autoconf initialisation. ##
|
|
## ------------------------ ##
|
|
AC_INIT([GNU Libtool],
|
|
m4_esyscmd([libltdl/config/git-version-gen .tarball-version]),
|
|
[bug-libtool@gnu.org])
|
|
m4_ifndef([AC_PACKAGE_URL],
|
|
[AC_SUBST([PACKAGE_URL], [http://www.gnu.org/s/libtool/])])
|
|
|
|
# Since we already declare these directories in this file, save those
|
|
# choices, and push the results into Makefile.am to avoid declaring
|
|
# them in two places making renames error prone, and where copies
|
|
# might get out of sync.
|
|
m4_define([AC_CONFIG_AUX_DIR],
|
|
m4_defn([AC_CONFIG_AUX_DIR])[AC_SUBST([aux_dir], [$1])])
|
|
m4_define([LT_CONFIG_LTDL_DIR],
|
|
m4_defn([LT_CONFIG_LTDL_DIR])[AC_SUBST([ltdl_dir], [$1])])
|
|
m4_define([AC_CONFIG_MACRO_DIR],
|
|
m4_defn([AC_CONFIG_MACRO_DIR])[AC_SUBST([macro_dir], [$1])])
|
|
|
|
AC_CONFIG_HEADERS([config.h:config-h.in])
|
|
AC_CONFIG_SRCDIR([libtoolize.m4sh])
|
|
LT_CONFIG_LTDL_DIR([libltdl], [nonrecursive])
|
|
AC_CONFIG_AUX_DIR([libltdl/config])
|
|
AC_CONFIG_MACRO_DIR([libltdl/m4])
|
|
AC_CONFIG_LIBOBJ_DIR([libltdl])
|
|
|
|
package_revision=`$SHELL $ac_aux_dir/git-version-gen .tarball-version`
|
|
AC_SUBST([package_revision])
|
|
|
|
## ------------------------ ##
|
|
## Autotest initialisation. ##
|
|
## ------------------------ ##
|
|
|
|
AC_CONFIG_TESTDIR([tests])
|
|
AC_SUBST([AUTOM4TE], [${AUTOM4TE=autom4te}])
|
|
AC_SUBST([AUTOTEST], ['$(AUTOM4TE) --language=autotest'])
|
|
|
|
|
|
## ---------------------------------------- ##
|
|
## Display a configure time version banner. ##
|
|
## ---------------------------------------- ##
|
|
|
|
# This is a sanity check so we can see which version is used in bug reports.
|
|
AS_BOX([Configuring AC_PACKAGE_TARNAME AC_PACKAGE_VERSION])
|
|
echo
|
|
|
|
|
|
## ------------------------ ##
|
|
## Automake Initialisation. ##
|
|
## ------------------------ ##
|
|
|
|
dnl These are bootstrap requirements! Once built, libtool may work with
|
|
dnl much older releases of autoconf and automake. See release notes.
|
|
dnl 1.11 is needed for color-tests, 1.11.1 fixes a security issue.
|
|
AM_INIT_AUTOMAKE([1.11.1 gnu subdir-objects dist-xz color-tests parallel-tests])
|
|
AM_SILENT_RULES([yes])
|
|
|
|
|
|
## ------------------------- ##
|
|
## Autobuild initialisation. ##
|
|
## ------------------------- ##
|
|
|
|
# You can set autobuild_mode at configure time to specify a "unique"
|
|
# string for this build.
|
|
: ${autobuild_mode=default}
|
|
AB_VERSION="AC_PACKAGE_VERSION"
|
|
AB_INIT([$autobuild_mode])
|
|
|
|
|
|
dnl We use m4sh to generate libtool's portable shell scripts
|
|
AC_SUBST([M4SH], ['$(AUTOM4TE) --language=m4sh'])
|
|
|
|
dnl Make sure config.status is regenerated when the version timestamp changes
|
|
AC_SUBST([CONFIG_STATUS_DEPENDENCIES], ['$(srcdir)/.version'])
|
|
|
|
|
|
## ------------------------------- ##
|
|
## Libtool specific configuration. ##
|
|
## ------------------------------- ##
|
|
|
|
AC_SUBST([aclocaldir], ["\${datadir}/aclocal"])
|
|
AC_SUBST([pkgdatadir], ["\${datadir}/$PACKAGE"])
|
|
|
|
AC_ARG_ENABLE(ltdl-install,
|
|
[AS_HELP_STRING([--disable-ltdl-install], [do not install libltdl])])
|
|
if test x"${enable_ltdl_install+set}" != xset; then
|
|
enable_ltdl_install=yes
|
|
fi
|
|
|
|
# The list of scripts required to build libltdl, and which need to be
|
|
# installed by libtoolize --ltdl, and consequently need to be placed in
|
|
# $pkgdatadir by our make install rule.
|
|
pkgaux_scripts="compile config.guess config.sub depcomp install-sh missing"
|
|
AC_SUBST([pkgaux_scripts])
|
|
|
|
# All subdirectories that are configured on demand, but that must be
|
|
# included in the distribution.
|
|
CONF_SUBDIRS="tests/cdemo tests/demo tests/depdemo tests/f77demo tests/fcdemo \
|
|
tests/mdemo tests/mdemo2 tests/pdemo tests/tagdemo"
|
|
AC_SUBST([CONF_SUBDIRS])
|
|
|
|
DIST_MAKEFILE_LIST=
|
|
for dir in $CONF_SUBDIRS; do
|
|
DIST_MAKEFILE_LIST="${DIST_MAKEFILE_LIST}$dir/Makefile "
|
|
done
|
|
AC_SUBST([DIST_MAKEFILE_LIST])
|
|
|
|
|
|
## ---------------- ##
|
|
## compiler checks. ##
|
|
## ---------------- ##
|
|
|
|
# Need to be sure that we have a working C compiler, otherwise even with
|
|
# a good C compiler: if the following C++ tests fail, the whole libtool
|
|
# build fails!
|
|
AC_PROG_CC
|
|
GL_EARLY
|
|
AM_PROG_CC_C_O
|
|
AC_PROG_CPP
|
|
|
|
## ----------------------- ##
|
|
## Libtool initialisation. ##
|
|
## ----------------------- ##
|
|
LT_INIT([dlopen win32-dll])
|
|
_LT_SET_OPTION([LTDL_INIT], [nonrecursive])
|
|
_LTDL_SETUP
|
|
|
|
# Enable all the language support we can
|
|
LT_LANG(C++)
|
|
LT_LANG(Fortran 77)
|
|
LT_LANG(Fortran)
|
|
LT_LANG(Go)
|
|
LT_LANG(Java)
|
|
LT_LANG(Windows Resource)
|
|
|
|
# Ensure the correct file name (and path) conversion function
|
|
# is available to the test suite.
|
|
AC_SUBST([to_host_file_cmd])dnl
|
|
AC_SUBST([to_tool_file_cmd])dnl
|
|
|
|
## --------------------------- ##
|
|
## Work out which tests to run ##
|
|
## --------------------------- ##
|
|
AM_CONDITIONAL(HAVE_CXX,[test -n "[$]_LT_TAGVAR(compiler, CXX)"])
|
|
AM_CONDITIONAL(HAVE_F77,[test -n "[$]_LT_TAGVAR(compiler, F77)"])
|
|
AM_CONDITIONAL(HAVE_FC,[test -n "[$]_LT_TAGVAR(compiler, FC)"])
|
|
AM_CONDITIONAL(HAVE_GCJ, [test -n "[$]_LT_TAGVAR(compiler, GCJ)"])
|
|
AM_CONDITIONAL(HAVE_RC, [test -n "[$]_LT_TAGVAR(compiler, RC)"])
|
|
|
|
## Whether `make' supports order-only prerequisites.
|
|
AC_CACHE_CHECK([whether ${MAKE-make} supports order-only prerequisites],
|
|
[lt_cv_make_order_only],
|
|
[mkdir conftest.dir
|
|
cd conftest.dir
|
|
touch b
|
|
touch a
|
|
cat >confmk << 'END'
|
|
a: b | c
|
|
a b c:
|
|
touch $[]@
|
|
END
|
|
touch c
|
|
if ${MAKE-make} -s -q -f confmk >/dev/null 2>&1; then
|
|
lt_cv_make_order_only=yes
|
|
else
|
|
lt_cv_make_order_only=no
|
|
fi
|
|
cd ..
|
|
rm -rf conftest.dir
|
|
])
|
|
if test $lt_cv_make_order_only = yes; then
|
|
ORDER='|'
|
|
else
|
|
ORDER=''
|
|
fi
|
|
AC_SUBST([ORDER])
|
|
|
|
## ---------------------- ##
|
|
## Gnulib initialisation. ##
|
|
## ---------------------- ##
|
|
GL_INIT
|
|
|
|
## ------------- ##
|
|
## Documentation ##
|
|
## ------------- ##
|
|
AM_MISSING_PROG([HELP2MAN], [help2man])
|
|
|
|
## -------- ##
|
|
## Outputs. ##
|
|
## -------- ##
|
|
AC_CONFIG_FILES([Makefile])
|
|
AC_OUTPUT
|