mirror of
git://git.savannah.gnu.org/libtool.git
synced 2025-01-24 14:24:59 +08:00
56c08a521e
used for files distributed with Libtool, and update license text to match. * Makefile.am, Makefile.maint README, README.alpha, THANKS, TODO, bootstrap, clcommit.m4sh, configure.ac, libltdl/Makefile.inc, libltdl/README, libltdl/argz.c, libltdl/argz_.h, libltdl/config/general.m4sh, libltdl/config/getopt.m4sh, libltdl/config/ltmain.m4sh, libltdl/config/mailnotify.m4sh, libltdl/config/mkstamp, libltdl/configure.ac, libltdl/libltdl/lt__alloc.h, libltdl/libltdl/lt__dirent.h, libltdl/libltdl/lt__glibc.h, libltdl/libltdl/lt__private.h, libltdl/libltdl/lt__strl.h, libltdl/libltdl/lt_dlloader.h, libltdl/libltdl/lt_error.h, libltdl/libltdl/lt_system.h, libltdl/libltdl/slist.h, libltdl/loaders/dld_link.c, libltdl/loaders/dlopen.c, libltdl/loaders/dyld.c, libltdl/loaders/load_add_on.c, libltdl/loaders/loadlibrary.c, libltdl/loaders/preopen.c, libltdl/loaders/shl_load.c, libltdl/lt__alloc.c, libltdl/lt__dirent.c, libltdl/lt__strl.c, libltdl/lt_dlloader.c, libltdl/lt_error.c, libltdl/ltdl.c, libltdl/ltdl.h, libltdl/m4/argz.m4, libltdl/m4/libtool.m4, libltdl/m4/ltdl.m4, libltdl/m4/ltoptions.m4, libltdl/m4/ltsugar.m4, libltdl/m4/ltversion.in, Jlibltdl/m4/ltversion.m4, libltdl/m4/lt~obsolete.m4, libltdl/slist.c, libtoolize.m4sh, tests/am-subdir.at, tests/cdemo-conf.test, tests/cdemo-exec.test, tests/cdemo-make.test, tests/cdemo-shared.test, tests/cdemo-static.test, tests/cdemo-undef.test, tests/cdemo/Makefile.am, tests/cdemo/configure.ac, tests/cdemo/foo.c, tests/cdemo/foo.h, tests/cdemo/main.c, tests/cmdline_wrap.at, tests/convenience.at, tests/defs.m4sh, tests/demo-conf.test, tests/demo-deplibs.test, tests/demo-exec.test, tests/demo-hardcode.test, tests/demo-inst.test, tests/demo-make.test, tests/demo-nofast.test, tests/demo-noinst-link.test, tests/demo-nopic.test, tests/demo-pic.test, tests/demo-relink.test, tests/demo-shared.test, tests/demo-static.test, tests/demo-unst.test, tests/demo/Makefile.am, tests/demo/configure.ac, tests/demo/dlmain.c, tests/demo/foo.c, tests/demo/foo.h, tests/demo/hell1.c, tests/demo/hell2.c, tests/demo/hello.c, tests/demo/main.c, tests/depdemo-conf.test, tests/depdemo-exec.test, tests/depdemo-inst.test, tests/depdemo-make.test, tests/depdemo-nofast.test, tests/depdemo-relink.test, tests/depdemo-shared.test, tests/depdemo-static.test, tests/depdemo-unst.test, tests/depdemo/Makefile.am, tests/depdemo/configure.ac, tests/depdemo/l1/Makefile.am, tests/depdemo/l1/l1.c, tests/depdemo/l1/l1.h, tests/depdemo/l2/Makefile.am, tests/depdemo/l2/l2.c, tests/depdemo/l2/l2.h, tests/depdemo/l3/Makefile.am, tests/depdemo/l3/l3.c, tests/depdemo/l3/l3.h, tests/depdemo/l4/Makefile.am, tests/depdemo/l4/l4.c, tests/depdemo/l4/l4.h, tests/depdemo/main.c, tests/depdemo/sysdep.h, tests/deplibs-ident.at, tests/destdir.at, tests/duplicate_conv.at, tests/duplicate_deps.at, tests/duplicate_members.at, tests/early-libtool.at, tests/export.at, tests/f77demo-conf.test, tests/f77demo-exec.test, tests/f77demo-make.test, tests/f77demo-shared.test, tests/f77demo-static.test, tests/f77demo/Makefile.am, tests/f77demo/configure.ac, tests/f77demo/cprogram.c, tests/f77demo/foo.h, tests/f77demo/fooc.c, tests/fail.at, tests/fcdemo-conf.test, tests/fcdemo-exec.test, tests/fcdemo-make.test, tests/fcdemo-shared.test, tests/fcdemo-static.test, tests/fcdemo/Makefile.am, tests/fcdemo/configure.ac, tests/fcdemo/cprogram.c, tests/fcdemo/foo.h, tests/fcdemo/fooc.c, tests/inherited_flags.at, tests/libtoolize.at, tests/link-2.test, tests/link-order.at, tests/link-order2.at, tests/link.test, tests/lt_dlexit.at, tests/mdemo-conf.test, tests/mdemo-dryrun.test, tests/mdemo-exec.test, tests/mdemo-inst.test, tests/mdemo-make.test, tests/mdemo-shared.test, tests/mdemo-static.test, tests/mdemo-unst.test, tests/mdemo/Makefile.am, tests/mdemo/configure.ac, tests/mdemo/foo.h, tests/mdemo/foo1.c, tests/mdemo/foo2.c, tests/mdemo/main.c, tests/mdemo/mlib.c, tests/mdemo/sub.c, tests/mdemo2-conf.test, tests/mdemo2-exec.test, tests/mdemo2-make.test, tests/mdemo2/Makefile.am, tests/mdemo2/configure.ac, tests/mdemo2/main.c, tests/nomode.test, tests/nonrecursive.at, tests/objectlist.test, tests/old-m4-iface.at, tests/pdemo-conf.test, tests/pdemo-exec.test, tests/pdemo-inst.test, tests/pdemo-make.test, tests/pdemo/Makefile.am, tests/pdemo/configure.ac, tests/pdemo/foo.h, tests/pdemo/longer_file_name_dlmain.c, tests/pdemo/longer_file_name_foo.c, tests/pdemo/longer_file_name_foo2.c, tests/pdemo/longer_file_name_hell1.c, tests/pdemo/longer_file_name_hell2.c, tests/pdemo/longer_file_name_hello.c, tests/pdemo/longer_file_name_main.c, tests/quote.test, tests/recursive.at, tests/search-path.at, tests/sh.test, tests/shlibpath.at, tests/standalone.at, tests/static.at, tests/stresstest.at, tests/subproject.at, tests/suffix.test, tests/tagdemo-conf.test, tests/tagdemo-exec.test, tests/tagdemo-make.test, tests/tagdemo-shared.test, tests/tagdemo-static.test, tests/tagdemo-undef.test, tests/tagdemo/Makefile.am, tests/tagdemo/baz.cpp, tests/tagdemo/baz.h, tests/tagdemo/configure.ac, tests/tagdemo/conv.cpp, tests/tagdemo/conv.h, tests/tagdemo/foo.cpp, tests/tagdemo/foo.h, tests/tagdemo/main.cpp, tests/tagtrace.test, tests/template.at, tests/testsuite.at: Apply correct license text according to the new rules set out in HACKING.
112 lines
3.5 KiB
Plaintext
112 lines
3.5 KiB
Plaintext
# ltsugar.m4 -- libtool m4 base layer. -*-Autoconf-*-
|
|
#
|
|
# Copyright (C) 2004, 2005 Free Software Foundation, Inc.
|
|
# Written by Gary V. Vaughan, 2004
|
|
#
|
|
# This file is free software; the Free Software Foundation gives
|
|
# unlimited permission to copy and/or distribute it, with or without
|
|
# modifications, as long as this notice is preserved.
|
|
|
|
# serial 3 ltsugar.m4
|
|
|
|
# This is to help aclocal find these macros, as it can't see m4_define.
|
|
AC_DEFUN([LTSUGAR_VERSION], [m4_if([0.1])])
|
|
|
|
|
|
# lt_join(SEP, ARG1, [ARG2...])
|
|
# -----------------------------
|
|
# Produce ARG1SEPARG2...SEPARGn, omitting [] arguments and their
|
|
# associated separator.
|
|
m4_define([lt_join],
|
|
[m4_case([$#],
|
|
[0], [m4_fatal([$0: too few arguments: $#])],
|
|
[1], [],
|
|
[2], [[$2]],
|
|
[m4_ifval([$2],
|
|
[[$2][]m4_foreach(_lt_Arg, lt_car([m4_shiftn(2, $@)]),
|
|
[_$0([$1], _lt_Arg)])],
|
|
[$0([$1], m4_shiftn(2, $@))])])[]dnl
|
|
])
|
|
m4_define([_lt_join],
|
|
[m4_ifval([$2],[$1][$2])[]dnl
|
|
])
|
|
|
|
|
|
# lt_car(LIST)
|
|
# lt_cdr(LIST)
|
|
# ------------
|
|
# Manipulate m4 lists.
|
|
# These macros are necessary as long as will still need to support
|
|
# Autoconf-2.59 which quotes differently.
|
|
m4_define([lt_car], [[$1]])
|
|
m4_define([lt_cdr],
|
|
[m4_if([$#], 0, [m4_fatal([$0: cannot be called without arguments])],
|
|
[$#], 1, [],
|
|
[m4_dquote(m4_shift($@))])])
|
|
m4_define([lt_unquote], $1)
|
|
|
|
|
|
# lt_combine(SEP, PREFIX-LIST, INFIX, SUFFIX1, [SUFFIX2...])
|
|
# ----------------------------------------------------------
|
|
# Produce a SEP delimited list of all paired combinations of elements of
|
|
# PREFIX-LIST with SUFFIX1 through SUFFIXn. Each element of the list
|
|
# has the form PREFIXmINFIXSUFFIXn.
|
|
m4_define([lt_combine],
|
|
[m4_if([$2], [], [],
|
|
[m4_if([$4], [], [],
|
|
[lt_join(m4_quote(m4_default([$1], [[, ]])),
|
|
lt_unquote(m4_split(m4_normalize(m4_foreach(_Lt_prefix, [$2],
|
|
[m4_foreach(_Lt_suffix, lt_car([m4_shiftn(3, $@)]),
|
|
[_Lt_prefix[]$3[]_Lt_suffix ])])))))])])dnl
|
|
])
|
|
|
|
|
|
# lt_if_append_uniq(MACRO-NAME, VARNAME, [SEPARATOR], [UNIQ], [NOT-UNIQ])
|
|
# -----------------------------------------------------------------------
|
|
# Iff MACRO-NAME does not yet contain VARNAME, then append it (delimited
|
|
# by SEPARATOR if supplied) and expand UNIQ, else NOT-UNIQ.
|
|
m4_define([lt_if_append_uniq],
|
|
[m4_ifdef([$1],
|
|
[m4_bmatch($3[]m4_defn([$1])$3, $3[]m4_re_escape([$2])$3,
|
|
[$5],
|
|
[m4_append([$1], [$2], [$3])$4])],
|
|
[m4_append([$1], [$2], [$3])$4])])
|
|
|
|
|
|
# lt_dict_add(DICT, KEY, VALUE)
|
|
# -----------------------------
|
|
m4_define([lt_dict_add],
|
|
[m4_define([$1($2)], [$4])])
|
|
|
|
|
|
# lt_dict_add_subkey(DICT, KEY, SUBKEY, VALUE)
|
|
# --------------------------------------------
|
|
m4_define([lt_dict_add_subkey],
|
|
[m4_define([$1($2:$3)], [$4])])
|
|
|
|
|
|
# lt_dict_fetch(DICT, KEY, [SUBKEY])
|
|
# ----------------------------------
|
|
m4_define([lt_dict_fetch],
|
|
[m4_ifval([$3],
|
|
m4_ifdef([$1($2:$3)], [m4_defn([$1($2:$3)])]),
|
|
m4_ifdef([$1($2)], [m4_defn([$1($2)])]))])
|
|
|
|
|
|
# lt_if_dict_fetch(DICT, KEY, [SUBKEY], VALUE, IF-TRUE, [IF-FALSE])
|
|
# -----------------------------------------------------------------
|
|
m4_define([lt_if_dict_fetch],
|
|
[m4_if(lt_dict_fetch([$1], [$2], [$3]), [$4],
|
|
[$5],
|
|
[$6])])
|
|
|
|
|
|
# lt_dict_filter(DICT, [SUBKEY], VALUE, [SEPARATOR], KEY, [...])
|
|
# --------------------------------------------------------------
|
|
m4_define([lt_dict_filter],
|
|
[m4_if([$5], [], [],
|
|
[lt_join(m4_quote(m4_default([$4], [[, ]])),
|
|
lt_unquote(m4_split(m4_normalize(m4_foreach(_Lt_key, lt_car([m4_shiftn(4, $@)]),
|
|
[lt_if_dict_fetch([$1], _Lt_key, [$2], [$3], [_Lt_key ])])))))])[]dnl
|
|
])
|