mirror of
git://git.savannah.gnu.org/libtool.git
synced 2024-12-21 06:59:11 +08:00
ef4442da9b
* libtoolize.m4sh (pkgdatadir, aclocaldir): Substituted from configure. (func_copy_all_from_path): Removed. No longer used. (func_copy_some_files): Simplify now that nothing is copied from a list of possible directories now. (func_scan_files): Remove directory readability check... (func_nonemptydir_p): ...in favour of a dedicated sanity check function called from the main body. (_lt_pkgvdatadir): Set pkgdatadir and aclocaldir appropriately if this is in the environment. * configure.ac: Tests for `ln' removed. (APIVERSION): Removed. * Makefile.am (pkgvdatadir, nobase_dist_pkgvdata_DATA) (nobase_pkgvdata_DATA): Renamed to... (pkgdatadir, nobase_dist_pkgdata_DATA, aclocalfiles): ...these respectively. (edit): Adjust for new variable names. (install-data-local): Don't bother to remove old macro files that will be overwritten by the installation, and perform a manual installation of $(aclocalfiles) to preserve timestamps. (install-exec-hook): Removed. No need to make versioned links. (uninstall-hook): No need to remove versioned links, but now we need to manually remove the manually installed $(aclocalfiles). * doc/libtool.texi: Remove bogus notes about setting ACLOCAL_AMFLAGS for versioned libtool installations. * NEWS: Remove parallel installation item.
187 lines
6.0 KiB
Plaintext
187 lines
6.0 KiB
Plaintext
## Process this file with autoconf to create configure. -*- autoconf -*-
|
|
# Copyright (C) 2001, 2004, 2005 Free Software Foundation, Inc.
|
|
#
|
|
# This program is free software; you can redistribute it and/or modify
|
|
# it under the terms of the GNU General Public License as published by
|
|
# the Free Software Foundation; either version 2 of the License, or
|
|
# (at your option) any later version.
|
|
#
|
|
# This program is distributed in the hope that it will be useful,
|
|
# but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
# GNU General Public License for more details.
|
|
#
|
|
# You should have received a copy of the GNU General Public License
|
|
# along with this program; if not, write to the Free Software
|
|
# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
|
|
# 02110-1301 USA
|
|
|
|
|
|
AC_PREREQ(2.59)dnl We use AS_HELP_STRING
|
|
dnl Oldest automake required for bootstrap is below in AM_INIT_AUTOMAKE.
|
|
|
|
|
|
## ------------------------ ##
|
|
## Autoconf initialisation. ##
|
|
## ------------------------ ##
|
|
AC_INIT([libtool], [2.1a], [bug-libtool@gnu.org])
|
|
AC_CONFIG_HEADERS([config.h:config-h.in])
|
|
AC_CONFIG_SRCDIR([libtoolize.in])
|
|
AC_CONFIG_AUX_DIR([config])
|
|
|
|
|
|
## ------------------------ ##
|
|
## Autotest initialisation. ##
|
|
## ------------------------ ##
|
|
|
|
AC_CONFIG_TESTDIR([tests])
|
|
AC_SUBST([AUTOM4TE], [autom4te])
|
|
AC_SUBST([AUTOTEST], ['$(AUTOM4TE) --language=autotest'])
|
|
|
|
|
|
## ---------------------------------------- ##
|
|
## Display a configure time version banner. ##
|
|
## ---------------------------------------- ##
|
|
|
|
# Calculating the previous version is somewhat involved, so do it once
|
|
# here, and SUBST the result for the maintainer release rules. The
|
|
# versioning scheme we use is described here:
|
|
# http://www.gnu.org/software/libtool/contribute.html
|
|
|
|
# First we break the version number up into its constituent parts.
|
|
lt_major=`echo "AC_PACKAGE_VERSION" | sed ['s,\..*$,,g']`
|
|
lt_minor=`echo "AC_PACKAGE_VERSION" | sed ['s,^[0-9]*\.\([0-9]*\).*$,\1,']`
|
|
lt_micro=`echo "AC_PACKAGE_VERSION" | sed ['s,^[0-9]*\.[0-9]*\(\.[0-9]*\).*$,\1,']`
|
|
lt_alpha=`echo "AC_PACKAGE_VERSION" | sed ['s,^[0-9.]*,,']`
|
|
|
|
test "$lt_minor" = "AC_PACKAGE_VERSION" && lt_minor=0
|
|
test "$lt_micro" = "AC_PACKAGE_VERSION" && lt_micro=""
|
|
|
|
# Then we try to work out what the release before this one would have been
|
|
# numbered. The only time we come unstuck is when this is the first release
|
|
# from a stable branch (lt_micro=lt_alpha=""), so LASTRELEASE is the last
|
|
# release from the old stable branch, and we don't know what version that
|
|
# was, so leave it unset so that the Makefile can complain.
|
|
case $lt_alpha in
|
|
[[ab]])
|
|
case $lt_micro in
|
|
[.[01]])
|
|
LASTRELEASE="$lt_major.$lt_minor" ;;
|
|
*)
|
|
LASTRELEASE="$lt_major.$lt_minor$lt_micro" ;;
|
|
esac
|
|
;;
|
|
[[cegikmoqsuwy]])
|
|
LASTRELEASE=`echo "AC_PACKAGE_VERSION" | tr 'c-y' 'b-w'` ;;
|
|
[[dfhjlnprtvxz]])
|
|
LASTRELEASE=`echo "AC_PACKAGE_VERSION" | tr 'd-z' 'b-x'` ;;
|
|
*) # No lt_alpha component
|
|
case $lt_micro in
|
|
.0)
|
|
LASTRELEASE="" ;;
|
|
.1)
|
|
LASTRELEASE="$lt_major.$lt_minor" ;;
|
|
.*)
|
|
lt_micro_value=`echo $lt_micro | sed 's,^\.,,'`
|
|
LASTRELEASE="$lt_major.$lt_minor.`expr $lt_micro_value - 1`" ;;
|
|
*)
|
|
LASTRELEASE="" ;;
|
|
esac
|
|
;;
|
|
esac
|
|
AC_SUBST([LASTRELEASE])
|
|
|
|
# This is a sanity check so we can see which version is used in bug reports.
|
|
# It is assumed that we only want to see the date extension for cvs libtool
|
|
# versions (i.e. "odd" letters) and not actual alpha releases.
|
|
TIMESTAMP=`${CONFIG_SHELL} ${ac_aux_dir}/mkstamp < ${srcdir}/ChangeLog`
|
|
package_revision=`( set $TIMESTAMP; echo $1; )`
|
|
case $lt_alpha in
|
|
[[bdfhjlnprtvxz]])
|
|
TIMESTAMP=
|
|
;;
|
|
esac
|
|
AS_BOX([Configuring AC_PACKAGE_TARNAME${TIMESTAMP:+" (Build:$TIMESTAMP)"} AC_PACKAGE_VERSION])
|
|
echo
|
|
AC_SUBST([TIMESTAMP])
|
|
AC_SUBST([package_revision])
|
|
|
|
|
|
## ------------------------ ##
|
|
## Automake Initialisation. ##
|
|
## ------------------------ ##
|
|
|
|
dnl These are bootstrap requirements, once built, libtool may work with
|
|
dnl much older releases of autoconf and automake. See release notes.
|
|
AM_INIT_AUTOMAKE([1.8 gnits dist-bzip2])dnl We use auto-m4_including
|
|
|
|
dnl We use m4sh to generate libtool's portable shell scripts
|
|
AC_SUBST([M4SH], ['$(AUTOM4TE) --language=m4sh'])
|
|
|
|
dnl Make sure config.status is regenerated when the version timestamp changes
|
|
AC_SUBST([CONFIG_STATUS_DEPENDENCIES], ['$(top_srcdir)/stamp-vcl'])
|
|
|
|
## ------------------------------- ##
|
|
## Libtool specific configuration. ##
|
|
## ------------------------------- ##
|
|
|
|
AC_SUBST([aclocaldir], ["\${datadir}/aclocal"])
|
|
AC_SUBST([pkgdatadir], ["\${datadir}/$PACKAGE"])
|
|
|
|
AC_ARG_ENABLE(ltdl-install,
|
|
[AS_HELP_STRING([--disable-ltdl-install], [do not install libltdl])])
|
|
if test x"${enable_ltdl_install+set}" != xset; then
|
|
enable_ltdl_install=yes
|
|
fi
|
|
|
|
# All subdirectories that are configured on demand, but that must be
|
|
# included in the distribution.
|
|
CONF_SUBDIRS="tests/cdemo tests/demo tests/depdemo tests/f77demo tests/mdemo \
|
|
tests/mdemo2 tests/pdemo tests/tagdemo"
|
|
AC_SUBST([CONF_SUBDIRS])
|
|
|
|
DIST_MAKEFILE_LIST=
|
|
for dir in $CONF_SUBDIRS; do
|
|
DIST_MAKEFILE_LIST="${DIST_MAKEFILE_LIST}$dir/Makefile "
|
|
done
|
|
AC_SUBST([DIST_MAKEFILE_LIST])
|
|
|
|
|
|
## ---------------- ##
|
|
## compiler checks. ##
|
|
## ---------------- ##
|
|
|
|
# Need to be sure that we have a working C compiler, otherwise even with
|
|
# a good C compiler: if the following C++ tests fail, the whole libtool
|
|
# build fails!
|
|
AC_PROG_CC
|
|
AC_PROG_CPP
|
|
|
|
## ----------------------- ##
|
|
## Libtool initialisation. ##
|
|
## ----------------------- ##
|
|
LT_INIT([dlopen win32-dll])
|
|
LTDL_INIT
|
|
|
|
# Enable all the language support we can
|
|
LT_LANG(C++)
|
|
LT_LANG(Fortran 77)
|
|
LT_LANG(Java)
|
|
LT_LANG(Windows Resource)
|
|
|
|
|
|
## --------------------------- ##
|
|
## Work out which tests to run ##
|
|
## --------------------------- ##
|
|
AM_CONDITIONAL(HAVE_CXX,[test -n "[$]_LT_TAGVAR(compiler, CXX)"])
|
|
AM_CONDITIONAL(HAVE_F77,[test -n "[$]_LT_TAGVAR(compiler, F77)"])
|
|
AM_CONDITIONAL(HAVE_GCJ, [test -n "[$]_LT_TAGVAR(compiler, GCJ)"])
|
|
AM_CONDITIONAL(HAVE_RC, [test -n "[$]_LT_TAGVAR(compiler, RC)"])
|
|
|
|
|
|
## -------- ##
|
|
## Outputs. ##
|
|
## -------- ##
|
|
AC_CONFIG_FILES([Makefile libltdl/Makefile])
|
|
AC_OUTPUT
|