mirror of
https://github.com/godotengine/godot.git
synced 2024-11-27 09:16:35 +08:00
d52b70fb5e
Include paths are processed from left to right, so we use Prepend to ensure that paths to bundled thirdparty files will have precedence over system paths (e.g. `/usr/include` should have lowest priority).
60 lines
1.8 KiB
Python
60 lines
1.8 KiB
Python
#!/usr/bin/env python
|
|
|
|
Import('env')
|
|
|
|
env_png = env.Clone()
|
|
|
|
# Thirdparty source files
|
|
if env['builtin_libpng']:
|
|
thirdparty_dir = "#thirdparty/libpng/"
|
|
thirdparty_sources = [
|
|
"png.c",
|
|
"pngerror.c",
|
|
"pngget.c",
|
|
"pngmem.c",
|
|
"pngpread.c",
|
|
"pngread.c",
|
|
"pngrio.c",
|
|
"pngrtran.c",
|
|
"pngrutil.c",
|
|
"pngset.c",
|
|
"pngtrans.c",
|
|
"pngwio.c",
|
|
"pngwrite.c",
|
|
"pngwtran.c",
|
|
"pngwutil.c",
|
|
]
|
|
thirdparty_sources = [thirdparty_dir + file for file in thirdparty_sources]
|
|
|
|
env_png.Prepend(CPPPATH=[thirdparty_dir])
|
|
# Needed for drivers includes and in platform/javascript
|
|
env.Prepend(CPPPATH=[thirdparty_dir])
|
|
|
|
# Currently .ASM filter_neon.S does not compile on NT.
|
|
import os
|
|
use_neon = "neon_enabled" in env and env["neon_enabled"] and os.name != "nt"
|
|
if use_neon:
|
|
env_png.Append(CPPFLAGS=["-DPNG_ARM_NEON_OPT=2"])
|
|
else:
|
|
env_png.Append(CPPFLAGS=["-DPNG_ARM_NEON_OPT=0"])
|
|
|
|
env_thirdparty = env_png.Clone()
|
|
env_thirdparty.disable_warnings()
|
|
env_thirdparty.add_source_files(env.drivers_sources, thirdparty_sources)
|
|
|
|
if use_neon:
|
|
env_neon = env_thirdparty.Clone()
|
|
if "S_compiler" in env:
|
|
env_neon['CC'] = env['S_compiler']
|
|
neon_sources = []
|
|
neon_sources.append(env_neon.Object(thirdparty_dir + "/arm/arm_init.c"))
|
|
neon_sources.append(env_neon.Object(thirdparty_dir + "/arm/filter_neon_intrinsics.c"))
|
|
neon_sources.append(env_neon.Object(thirdparty_dir + "/arm/filter_neon.S"))
|
|
neon_sources.append(env_neon.Object(thirdparty_dir + "/arm/palette_neon_intrinsics.c"))
|
|
env.drivers_sources += neon_sources
|
|
|
|
# Godot source files
|
|
env_png.add_source_files(env.drivers_sources, "*.cpp")
|
|
|
|
Export('env')
|