mirror of
git://sourceware.org/git/glibc.git
synced 2024-12-27 04:41:02 +08:00
5de92c17d7
* data/localplt-arm-linux-gnueabi.data: New. * sysdeps/arm/bsd-_setjmp.S: Use HIDDEN_JUMPTARGET to call __sigsetjmp. * sysdeps/arm/bsd-setjmp.S: Likewise. * sysdeps/arm/eabi/aeabi_localeconv.c: Use __localeconv. * sysdeps/arm/eabi/find_exidx.c (__gnu_Unwind_Find_exidx): Use __dl_iterate_phdr. * sysdeps/arm/eabi/setjmp.S: Add hidden_def (__sigsetjmp). * sysdeps/arm/memmove.S: Use HIDDEN_JUMPTARGET to call memcpy from within libc. * sysdeps/arm/setjmp.S: Add hidden_def (__sigsetjmp). * sysdeps/unix/sysv/linux/arm/clone.S: Use HIDDEN_JUMPTARGET to call _exit. * sysdeps/unix/sysv/linux/arm/ioperm.c (init_iosys): Use __sysctl, __readlink and fgets_unlocked. (_ioperm): Use __open and __close.
108 lines
2.5 KiB
ArmAsm
108 lines
2.5 KiB
ArmAsm
/* Copyright (C) 1996, 1997, 1998, 1999, 2002, 2005, 2008
|
|
Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
Contributed by Pat Beirne <patb@corelcomputer.com>
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, write to the Free
|
|
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
|
|
02111-1307 USA. */
|
|
|
|
/* clone() is even more special than fork() as it mucks with stacks
|
|
and invokes a function in the right context after its all over. */
|
|
|
|
#include <sysdep.h>
|
|
#define _ERRNO_H 1
|
|
#include <bits/errno.h>
|
|
|
|
#define CLONE_VM 0x00000100
|
|
#define CLONE_THREAD 0x00010000
|
|
|
|
/* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
|
|
pid_t *ptid, struct user_desc *tls, pid_t *ctid); */
|
|
|
|
.text
|
|
ENTRY(__clone)
|
|
@ sanity check args
|
|
cmp r0, #0
|
|
cmpne r1, #0
|
|
moveq r0, #-EINVAL
|
|
beq PLTJMP(syscall_error)
|
|
|
|
@ insert the args onto the new stack
|
|
str r3, [r1, #-4]!
|
|
str r0, [r1, #-4]!
|
|
|
|
@ do the system call
|
|
@ get flags
|
|
mov r0, r2
|
|
#ifdef RESET_PID
|
|
mov ip, r2
|
|
#endif
|
|
@ new sp is already in r1
|
|
#ifdef __ARM_EABI__
|
|
stmfd sp!, {r4, r7}
|
|
#else
|
|
str r4, [sp, #-8]!
|
|
#endif
|
|
ldr r2, [sp, #8]
|
|
ldr r3, [sp, #12]
|
|
ldr r4, [sp, #16]
|
|
#ifdef __ARM_EABI__
|
|
ldr r7, =SYS_ify(clone)
|
|
swi 0x0
|
|
#else
|
|
swi SYS_ify(clone)
|
|
#endif
|
|
cmp r0, #0
|
|
beq 1f
|
|
#ifdef __ARM_EABI__
|
|
ldmfd sp!, {r4, r7}
|
|
#else
|
|
ldr r4, [sp], #8
|
|
#endif
|
|
blt PLTJMP(C_SYMBOL_NAME(__syscall_error))
|
|
RETINSTR(, lr)
|
|
|
|
1:
|
|
#ifdef RESET_PID
|
|
tst ip, #CLONE_THREAD
|
|
bne 3f
|
|
mov r0, #0xffff0fff
|
|
mov lr, pc
|
|
sub pc, r0, #31
|
|
mov r1, r0
|
|
tst ip, #CLONE_VM
|
|
movne r0, #-1
|
|
#ifdef __ARM_EABI__
|
|
ldr r7, =SYS_ify(getpid)
|
|
swieq 0x0
|
|
#else
|
|
swieq SYS_ify(getpid)
|
|
#endif
|
|
str r0, [r1, #PID_OFFSET]
|
|
str r0, [r1, #TID_OFFSET]
|
|
3:
|
|
#endif
|
|
@ pick the function arg and call address off the stack and execute
|
|
ldr r0, [sp, #4]
|
|
mov lr, pc
|
|
ldr pc, [sp], #8
|
|
|
|
@ and we are done, passing the return value through r0
|
|
b PLTJMP(HIDDEN_JUMPTARGET(_exit))
|
|
|
|
PSEUDO_END (__clone)
|
|
|
|
weak_alias (__clone, clone)
|