mirror of
git://sourceware.org/git/glibc.git
synced 2024-12-21 04:31:04 +08:00
4d37c8aa01
2004-12-22 Steven Munroe <sjmunroe@us.ibm.com> * math/libm-test.inc (rint_test_tonearest): New test. (rint_test_towardzero): New test. (rint_test_downward): New test. (rint_test_upward): New test. * sysdeps/powerpc/powerpc32/fpu/s_ceil.S: Fix -0.0 case. Remove redundant const values. * sysdeps/powerpc/powerpc32/fpu/s_ceilf.S: Fix -0.0 case. Remove redundant const values. Use float const. * sysdeps/powerpc/powerpc32/fpu/s_floor.S: Fix -0.0 case. * sysdeps/powerpc/powerpc32/fpu/s_floorf.S: Fix -0.0 case. Use float const. * sysdeps/powerpc/powerpc32/fpu/s_rint.S: Fix -0.0 case. * sysdeps/powerpc/powerpc32/fpu/s_rintf.S: Fix -0.0 case. Use float const. * sysdeps/powerpc/powerpc32/fpu/s_round.S: Fix -0.0 case. Remove redundant const values. * sysdeps/powerpc/powerpc32/fpu/s_roundf.S: Fix -0.0 case. Remove redundant const values. Use float const. * sysdeps/powerpc/powerpc32/fpu/s_trunc.S: Fix -0.0 case. Remove redundant const values. * sysdeps/powerpc/powerpc32/fpu/s_truncf.S: Fix -0.0 case. Remove redundant const values. Use float const. * sysdeps/powerpc/powerpc64/fpu/s_ceil.S: Use EALIGN for Quadword alignment. Fix -0.0 case. Remove redundant const values. * sysdeps/powerpc/powerpc64/fpu/s_ceilf.S: Use EALIGN for Quadword alignment. Fix -0.0 case. Remove redundant const values. Use float const. * sysdeps/powerpc/powerpc64/fpu/s_floor.S: Use EALIGN for Quadword alignment. Fix -0.0 case. * sysdeps/powerpc/powerpc64/fpu/s_floorf.S: Use EALIGN for Quadword alignment. Fix -0.0 case. Use float const. * sysdeps/powerpc/powerpc64/fpu/s_rint.S: Use EALIGN for Quadword alignment. Fix -0.0 case. * sysdeps/powerpc/powerpc64/fpu/s_rintf.S: Use EALIGN for Quadword alignment. Fix -0.0 case. Use float const. * sysdeps/powerpc/powerpc64/fpu/s_round.S: Use EALIGN for Quadword alignment. Fix -0.0 case. Remove redundant const values. * sysdeps/powerpc/powerpc64/fpu/s_roundf.S: Use EALIGN for Quadword alignment. Fix -0.0 case. Remove redundant const values. Use float const. * sysdeps/powerpc/powerpc64/fpu/s_trunc.S: Use EALIGN for Quadword alignment. Fix -0.0 case. * sysdeps/powerpc/powerpc64/fpu/s_truncf.S: Use EALIGN for Quadword alignment. Fix -0.0 case. Remove redundant const values. Use float const.
98 lines
2.8 KiB
ArmAsm
98 lines
2.8 KiB
ArmAsm
/* roundf function. PowerPC32 version.
|
|
Copyright (C) 2004 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, write to the Free
|
|
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
|
|
02111-1307 USA. */
|
|
|
|
#include <sysdep.h>
|
|
|
|
.section .rodata
|
|
.align 2
|
|
.type TWO23.0,@object
|
|
.size TWO23.0,4
|
|
TWO23.0:
|
|
.long 0x4b000000
|
|
.type POINTFIVE.0,@object
|
|
.size POINTFIVE.0,4
|
|
POINTFIVE.0:
|
|
.long 0x3f000000
|
|
|
|
.section .rodata.cst4,"aM",@progbits,4
|
|
.align 2
|
|
.LC0: /* 2**23 */
|
|
.long 0x4b000000
|
|
.LC1: /* 0.5 */
|
|
.long 0x3f000000
|
|
|
|
/* float [fp1] roundf (float x [fp1])
|
|
IEEE 1003.1 round function. IEEE specifies "round to the nearest
|
|
integer value, rounding halfway cases away from zero, regardless of
|
|
the current rounding mode." However PowerPC Architecture defines
|
|
"Round to Nearest" as "Choose the best approximation. In case of a
|
|
tie, choose the one that is even (least significant bit o).".
|
|
So we can't use the PowerPC "Round to Nearest" mode. Instead we set
|
|
"Round toward Zero" mode and round by adding +-0.5 before rounding
|
|
to the integer value. */
|
|
|
|
ENTRY (__roundf )
|
|
mffs fp11 /* Save current FPU rounding mode. */
|
|
#ifdef SHARED
|
|
mflr r11
|
|
bl _GLOBAL_OFFSET_TABLE_@local-4
|
|
mflr r10
|
|
lwz r9,.LC0@got(10)
|
|
mtlr r11
|
|
lfs fp13,0(r9)
|
|
#else
|
|
lis r9,.LC0@ha
|
|
lfs fp13,.LC0@l(r9)
|
|
#endif
|
|
fabs fp0,fp1
|
|
fsubs fp12,fp13,fp13 /* generate 0.0 */
|
|
fcmpu cr7,fp0,fp13 /* if (fabs(x) > TWO23) */
|
|
fcmpu cr6,fp1,fp12 /* if (x > 0.0) */
|
|
bnllr- cr7
|
|
mtfsfi 7,1 /* Set rounding mode toward 0. */
|
|
#ifdef SHARED
|
|
lwz r9,.LC1@got(10)
|
|
lfs fp10,0(r9)
|
|
#else
|
|
lis r9,.LC1@ha
|
|
lfs fp10,.LC1@l(r9)
|
|
#endif
|
|
ble- cr6,.L4
|
|
fadds fp1,fp1,fp10 /* x+= 0.5; */
|
|
fadds fp1,fp1,fp13 /* x+= TWO23; */
|
|
fsubs fp1,fp1,fp13 /* x-= TWO23; */
|
|
fabs fp1,fp1 /* if (x == 0.0) */
|
|
/* x = 0.0; */
|
|
mtfsf 0x01,fp11 /* restore previous rounding mode. */
|
|
blr
|
|
.L4:
|
|
fsubs fp9,fp1,fp10 /* x+= 0.5; */
|
|
bge- cr6,.L9 /* if (x < 0.0) */
|
|
fsubs fp1,fp9,fp13 /* x-= TWO23; */
|
|
fadds fp1,fp1,fp13 /* x+= TWO23; */
|
|
fnabs fp1,fp1 /* if (x == 0.0) */
|
|
/* x = -0.0; */
|
|
.L9:
|
|
mtfsf 0x01,fp11 /* restore previous rounding mode. */
|
|
blr
|
|
END (__roundf)
|
|
|
|
weak_alias (__roundf, roundf)
|
|
|