mirror of
git://sourceware.org/git/glibc.git
synced 2024-12-21 04:31:04 +08:00
24c177a079
* sysdeps/alpha/_mcount.S, sysdeps/alpha/bb_init_func.S, sysdeps/alpha/bsd-setjmp.S, sysdeps/alpha/ffs.S, sysdeps/alpha/htonl.S, sysdeps/alpha/htons.S, sysdeps/alpha/memchr.S, sysdeps/alpha/setjmp.S, sysdeps/alpha/strlen.S, sysdeps/alpha/udiv_qrnnd.S, sysdeps/unix/sysv/linux/alpha/brk.S, sysdeps/unix/sysv/linux/alpha/ieee_get_fp_control.S, sysdeps/unix/sysv/linux/alpha/ieee_set_fp_control.S, sysdeps/unix/sysv/linux/alpha/pipe.S, sysdeps/unix/sysv/linux/sigsuspend.S, sysdeps/unix/sysv/linux/alpha/syscall.S, sysdeps/unix/sysv/linux/alpha/sysdep.S: Remove include of regdef.h. sysdep.h includes it now. Replace ENTRY by LEAF with appropriate framesize declaration. Replace "lda pv,sym/jsr pv" by "jsr sym".
152 lines
2.7 KiB
ArmAsm
152 lines
2.7 KiB
ArmAsm
# Alpha 21064 __udiv_qrnnd
|
|
|
|
# Copyright (C) 1992, 1994, 1995 Free Software Foundation, Inc.
|
|
|
|
# This file is part of the GNU MP Library.
|
|
|
|
# The GNU MP Library is free software; you can redistribute it and/or modify
|
|
# it under the terms of the GNU Library General Public License as published by
|
|
# the Free Software Foundation; either version 2 of the License, or (at your
|
|
# option) any later version.
|
|
|
|
# The GNU MP Library is distributed in the hope that it will be useful, but
|
|
# WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
|
|
# or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Library General Public
|
|
# License for more details.
|
|
|
|
# You should have received a copy of the GNU Library General Public License
|
|
# along with the GNU MP Library; see the file COPYING.LIB. If not, write to
|
|
# the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
|
|
# MA 02111-1307, USA.
|
|
|
|
#include <sysdep.h>
|
|
|
|
.set noreorder
|
|
.set noat
|
|
|
|
.text
|
|
|
|
LEAF(__udiv_qrnnd, 0)
|
|
|
|
.prologue 0
|
|
#define cnt $2
|
|
#define tmp $3
|
|
#define rem_ptr $16
|
|
#define n1 $17
|
|
#define n0 $18
|
|
#define d $19
|
|
#define qb $20
|
|
|
|
ldiq cnt,16
|
|
blt d,.Largedivisor
|
|
|
|
.Loop1: cmplt n0,0,tmp
|
|
addq n1,n1,n1
|
|
bis n1,tmp,n1
|
|
addq n0,n0,n0
|
|
cmpule d,n1,qb
|
|
subq n1,d,tmp
|
|
cmovne qb,tmp,n1
|
|
bis n0,qb,n0
|
|
cmplt n0,0,tmp
|
|
addq n1,n1,n1
|
|
bis n1,tmp,n1
|
|
addq n0,n0,n0
|
|
cmpule d,n1,qb
|
|
subq n1,d,tmp
|
|
cmovne qb,tmp,n1
|
|
bis n0,qb,n0
|
|
cmplt n0,0,tmp
|
|
addq n1,n1,n1
|
|
bis n1,tmp,n1
|
|
addq n0,n0,n0
|
|
cmpule d,n1,qb
|
|
subq n1,d,tmp
|
|
cmovne qb,tmp,n1
|
|
bis n0,qb,n0
|
|
cmplt n0,0,tmp
|
|
addq n1,n1,n1
|
|
bis n1,tmp,n1
|
|
addq n0,n0,n0
|
|
cmpule d,n1,qb
|
|
subq n1,d,tmp
|
|
cmovne qb,tmp,n1
|
|
bis n0,qb,n0
|
|
subq cnt,1,cnt
|
|
bgt cnt,.Loop1
|
|
stq n1,0(rem_ptr)
|
|
bis $31,n0,$0
|
|
ret $31,($26),1
|
|
|
|
.Largedivisor:
|
|
and n0,1,$4
|
|
|
|
srl n0,1,n0
|
|
sll n1,63,tmp
|
|
or tmp,n0,n0
|
|
srl n1,1,n1
|
|
|
|
and d,1,$6
|
|
srl d,1,$5
|
|
addq $5,$6,$5
|
|
|
|
.Loop2: cmplt n0,0,tmp
|
|
addq n1,n1,n1
|
|
bis n1,tmp,n1
|
|
addq n0,n0,n0
|
|
cmpule $5,n1,qb
|
|
subq n1,$5,tmp
|
|
cmovne qb,tmp,n1
|
|
bis n0,qb,n0
|
|
cmplt n0,0,tmp
|
|
addq n1,n1,n1
|
|
bis n1,tmp,n1
|
|
addq n0,n0,n0
|
|
cmpule $5,n1,qb
|
|
subq n1,$5,tmp
|
|
cmovne qb,tmp,n1
|
|
bis n0,qb,n0
|
|
cmplt n0,0,tmp
|
|
addq n1,n1,n1
|
|
bis n1,tmp,n1
|
|
addq n0,n0,n0
|
|
cmpule $5,n1,qb
|
|
subq n1,$5,tmp
|
|
cmovne qb,tmp,n1
|
|
bis n0,qb,n0
|
|
cmplt n0,0,tmp
|
|
addq n1,n1,n1
|
|
bis n1,tmp,n1
|
|
addq n0,n0,n0
|
|
cmpule $5,n1,qb
|
|
subq n1,$5,tmp
|
|
cmovne qb,tmp,n1
|
|
bis n0,qb,n0
|
|
subq cnt,1,cnt
|
|
bgt cnt,.Loop2
|
|
|
|
addq n1,n1,n1
|
|
addq $4,n1,n1
|
|
bne $6,.LOdd
|
|
stq n1,0(rem_ptr)
|
|
bis $31,n0,$0
|
|
ret $31,($26),1
|
|
|
|
.LOdd:
|
|
/* q' in n0. r' in n1 */
|
|
addq n1,n0,n1
|
|
cmpult n1,n0,tmp # tmp := carry from addq
|
|
beq tmp,.LLp6
|
|
addq n0,1,n0
|
|
subq n1,d,n1
|
|
.LLp6: cmpult n1,d,tmp
|
|
bne tmp,.LLp7
|
|
addq n0,1,n0
|
|
subq n1,d,n1
|
|
.LLp7:
|
|
stq n1,0(rem_ptr)
|
|
bis $31,n0,$0
|
|
ret $31,($26),1
|
|
|
|
.end __udiv_qrnnd
|