glibc/sysdeps/unix/sysv/linux/alpha/llseek.S

/* Copyright (C) 1993, 1995, 1996 Free Software Foundation, Inc.
   This file is part of the GNU C Library.
   Contributed by David Mosberger <davidm@cs.arizona.edu>, 1995.

   The GNU C Library is free software; you can redistribute it and/or
   modify it under the terms of the GNU Library General Public License as
   published by the Free Software Foundation; either version 2 of the
   License, or (at your option) any later version.

   The GNU C Library is distributed in the hope that it will be useful,
   but WITHOUT ANY WARRANTY; without even the implied warranty of
   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
   Library General Public License for more details.

   You should have received a copy of the GNU Library General Public
   License along with the GNU C Library; see the file COPYING.LIB.  If not,
   write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
   Boston, MA 02111-1307, USA.  */

/* For compatibility only: a "long" is 64 bits on the Alpha, so
   llseek() isn't really needed.  But there are some programs out
   there who may depend on it being around.  */

#include <sysdep.h>

	.text
ENTRY(llseek)
#ifdef PROF
	ldgp	gp, 0(pv)
	.set noat
	lda	AT, _mcount
	jsr	AT, (AT), _mcount
	.set at
	.prologue 1
#else
	.prologue 0
#endif

	sll	a1, 32, a1	/* build a 64 bit ofs out of 32 bit operands */
	zap	a2, 0xf0, a2
	mov	a3, t0		/* save result address */
	bis	a2, a1, a1

	mov	a4, a2		/* shift down whence */

	ldi	v0, __NR_lseek
	call_pal PAL_callsys
	bne	a3, error

	stq	v0, 0(t0)
	ret

error:
#ifndef PROF
	br	gp, 1f
1:	ldgp	gp, 0(gp)
#endif
	jmp	zero, __syscall_error

	END(llseek)