mirror of
git://gcc.gnu.org/git/gcc.git
synced 2024-12-22 21:09:40 +08:00
905280ac0c
* configure.in (multiosdir): Set to nothing if compiler is not GCC or if it doesn't support -print-multi-os-directory. * configure: Rebuilt. From-SVN: r63153
156 lines
4.3 KiB
Plaintext
156 lines
4.3 KiB
Plaintext
dnl Process this with autoconf to create configure
|
|
|
|
AC_INIT(zlib.h)
|
|
|
|
# This works around the fact that libtool configuration may change LD
|
|
# for this particular configuration, but some shells, instead of
|
|
# keeping the changes in LD private, export them just because LD is
|
|
# exported.
|
|
ORIGINAL_LD_FOR_MULTILIBS=$LD
|
|
|
|
dnl We may get other options which we dont document:
|
|
dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
|
|
|
|
if test "x[$]{with_target_subdir}" != x && \
|
|
test "[$]{srcdir}" = "."; then
|
|
if test "[$]{with_target_subdir}" != "."; then
|
|
zlib_basedir="[$]{srcdir}/[$]{with_multisrctop}../"
|
|
else
|
|
zlib_basedir="[$]{srcdir}/[$]{with_multisrctop}"
|
|
fi
|
|
else
|
|
zlib_basedir="[$]{srcdir}/"
|
|
fi
|
|
AC_SUBST(zlib_basedir)
|
|
AC_CONFIG_AUX_DIR($zlib_basedir..)
|
|
if :; then :; else
|
|
# This overrides the previous occurrence for automake, but not for
|
|
# autoconf, which is exactly what we want.
|
|
AC_CONFIG_AUX_DIR(..)
|
|
fi
|
|
|
|
AC_CANONICAL_SYSTEM
|
|
|
|
# This works around an automake problem.
|
|
mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
|
|
AC_SUBST(mkinstalldirs)
|
|
|
|
AM_INIT_AUTOMAKE(zlib, 1.1.3)
|
|
|
|
AM_MAINTAINER_MODE
|
|
|
|
dnl We use these options to decide which functions to include.
|
|
AC_ARG_WITH(target-subdir,
|
|
[ --with-target-subdir=SUBDIR
|
|
configuring in a subdirectory])
|
|
AC_ARG_WITH(cross-host,
|
|
[ --with-cross-host=HOST configuring with a cross compiler])
|
|
|
|
dnl Default to --enable-multilib
|
|
AC_ARG_ENABLE(multilib,
|
|
[ --enable-multilib build many library versions (default)],
|
|
[case "${enableval}" in
|
|
yes) multilib=yes ;;
|
|
no) multilib=no ;;
|
|
*) AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
|
|
esac], [test -z "$with_target_subdir" && multilib=no || multilib=yes])dnl
|
|
|
|
AC_ARG_WITH(system-zlib,
|
|
[ --with-system-zlib use installed libz])
|
|
|
|
LIB_AC_PROG_CC
|
|
# We need AC_EXEEXT to keep automake happy in cygnus mode. However,
|
|
# at least currently, we never actually build a program, so we never
|
|
# need to use $(EXEEXT). Moreover, the test for EXEEXT normally
|
|
# fails, because we are probably configuring with a cross compiler
|
|
# which cant create executables. So we include AC_EXEEXT to keep
|
|
# automake happy, but we dont execute it, since we dont care about
|
|
# the result.
|
|
if false; then
|
|
# autoconf 2.50 runs AC_EXEEXT by default, and the macro expands
|
|
# to nothing, so nothing would remain between `then' and `fi' if it
|
|
# were not for the `:' below.
|
|
:
|
|
AC_EXEEXT
|
|
fi
|
|
AM_PROG_LIBTOOL
|
|
|
|
if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
|
|
COMPPATH=.
|
|
else
|
|
COMPPATH=..
|
|
fi
|
|
AC_SUBST(COMPPATH)
|
|
|
|
# Find CPP now so that any conditional tests below won't do it and
|
|
# thereby make the resulting definitions conditional.
|
|
AC_PROG_CPP
|
|
|
|
if test -n "$with_cross_host"; then
|
|
# We are being configured with a cross compiler. AC_REPLACE_FUNCS
|
|
# may not work correctly, because the compiler may not be able to
|
|
# link executables.
|
|
|
|
# We assume newlib. This lets us hard-code the functions we know
|
|
# we'll have.
|
|
AC_DEFINE(HAVE_MEMCPY)
|
|
AC_DEFINE(HAVE_STRERROR)
|
|
|
|
# We ignore --with-system-zlib in this case.
|
|
target_all=libzgcj.la
|
|
else
|
|
AC_FUNC_MMAP
|
|
AC_CHECK_FUNCS(memcpy strerror)
|
|
|
|
if test "$with_system_zlib" = yes; then
|
|
AC_CHECK_LIB(z, deflate, target_all=, target_all=libzgcj.la)
|
|
else
|
|
target_all=libzgcj.la
|
|
fi
|
|
fi
|
|
|
|
AC_SUBST(target_all)
|
|
|
|
AC_CHECK_HEADERS(unistd.h)
|
|
|
|
if test -n "$with_cross_host" &&
|
|
test x"$with_cross_host" != x"no"; then
|
|
toolexecdir='$(exec_prefix)/$(target_alias)'
|
|
toolexeclibdir='$(toolexecdir)/lib'
|
|
else
|
|
toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
|
|
toolexeclibdir='$(libdir)'
|
|
fi
|
|
if test "$GCC" = yes && $CC -print-multi-os-directory > /dev/null 2>&1; then
|
|
multiosdir=/`$CC -print-multi-os-directory`
|
|
else
|
|
multiosdir=
|
|
fi
|
|
toolexeclibdir=${toolexeclibdir}${multiosdir}
|
|
AC_SUBST(toolexecdir)
|
|
AC_SUBST(toolexeclibdir)
|
|
|
|
AM_CONDITIONAL(TARGET_LIBRARY, test -n "$with_target_subdir")
|
|
|
|
if test "${multilib}" = "yes"; then
|
|
multilib_arg="--enable-multilib"
|
|
else
|
|
multilib_arg=
|
|
fi
|
|
|
|
AC_OUTPUT(Makefile,
|
|
[if test -n "$CONFIG_FILES"; then
|
|
LD="${ORIGINAL_LD_FOR_MULTILIBS}"
|
|
ac_file=Makefile . ${zlib_basedir}/../config-ml.in
|
|
fi],
|
|
srcdir=${srcdir}
|
|
host=${host}
|
|
target=${target}
|
|
with_multisubdir=${with_multisubdir}
|
|
ac_configure_args="${multilib_arg} ${ac_configure_args}"
|
|
CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
|
|
zlib_basedir=${zlib_basedir}
|
|
CC="${CC}"
|
|
CXX="${CXX}"
|
|
)
|