mirror of
git://gcc.gnu.org/git/gcc.git
synced 2024-12-28 04:44:38 +08:00
51122a4242
2002-08-31 Phil Edwards <pme@gcc.gnu.org> * acinclude.m4: Minor comment tweaks. * docs/html/makedoc.awk: New file... * docs/html/Makefile: ...called from here... * docs/html/documentation.html: ...to help generate this. * docs/html/21_strings/howto.html: Prepare for new entry. * include/bits/basic_string.h: Initial basic_stirng hook for doxygen. Remove trailing whitespace. * include/bits/char_traits.h: Point to onlinedocs for new entry. * include/bits/stringfwd.h: Add doxygen hooks for string and wstring typedefs. From-SVN: r56711
70 lines
1.7 KiB
Awk
70 lines
1.7 KiB
Awk
# Take apart bits of HTML and puts them back together again in new and
|
|
# fascinating ways. Copyright (C) 2002 Free Software Foundation, Inc.
|
|
# Contributed by Phil Edwards <pme@gcc.gnu.org>. Simple two-state automaton
|
|
# inspired by Richard Henderson's gcc/mkmap-symver.awk.
|
|
|
|
# 'file' is the name of the file on stdin
|
|
# 'title' is the text to print at the start of the list
|
|
|
|
BEGIN {
|
|
state = "looking";
|
|
entries = 0;
|
|
printf (" <li>%s</li>\n", title);
|
|
printf (" <ul>\n");
|
|
}
|
|
|
|
# Searching for the little table of contents at the top.
|
|
state == "looking" && /^<h1>Contents/ {
|
|
state = "entries";
|
|
next;
|
|
}
|
|
|
|
# Ignore everything else up to that point.
|
|
state == "looking" {
|
|
next;
|
|
}
|
|
|
|
# An entry in the table of contents. Pull that line apart.
|
|
state == "entries" && /<li>/ {
|
|
extract_info($0);
|
|
next;
|
|
}
|
|
|
|
# End of the list. Don't bother reading the rest of the file. (It could
|
|
# also contain more <li>'s, so that would be incorrect as well as wasteful.)
|
|
state == "entries" && /^<\/ul>/ {
|
|
exit;
|
|
}
|
|
|
|
END {
|
|
for (i = 0; i < entries; i++)
|
|
printf (" %s\n", entry[i]);
|
|
printf (" </ul>\n\n");
|
|
}
|
|
|
|
function extract_info(line) {
|
|
# thistarget will be things like "#5" or "elsewhere.html"
|
|
match(line,"href=\".*\"");
|
|
thistarget = substr(line,RSTART+6,RLENGTH-7);
|
|
|
|
# take apart the filename
|
|
split(file,X,"/");
|
|
if (thistarget ~ /^#/) {
|
|
# local name, use directory and filename
|
|
target = file thistarget
|
|
} else {
|
|
# different file, only use directory
|
|
target = X[1] "/" thistarget
|
|
}
|
|
|
|
# visible text
|
|
gsub("</a>","",line);
|
|
start = index(line,"\">") + 2;
|
|
thistext = substr(line,start);
|
|
|
|
# Assemble and store the HTML for later output.
|
|
entry[entries++] = "<li><a href=\"" target "\">" thistext "</a></li>"
|
|
}
|
|
|
|
# vim:sw=2
|