mirror of
https://github.com/curl/curl.git
synced 2025-03-07 15:27:17 +08:00
7b88bb4443
Make `test-ci` not depend on the `testdeps` target. `test-ci` is designed to run curl tests in CI. In CI we build all necessary dependencies explicitly beforehand, and they are always ready when calling the `test-ci` step. Thus, it isn't necessary to enforce them via a dependency rule. Dropping it saves redundant work and delay in CI jobs. The `testdeps` dependency should not normally be a problem. It's supposed to be a no-op if those targets are already built. In practice however, it causes a delay and/or an actual rebuild of those dependencies depending on generator (= build tool) used and other factors. As observed in the GHA/windows workflow, the `testdeps` dependency: - with Ninja, causes no delay, and no extra work: https://github.com/curl/curl/actions/runs/10980099984/job/30485440389#step:25:18 - with GNU Make, caused a re-evaluation of `testdeps` targets, but did not actually rebuild them. This re-evaluation took a noticeable time (esp. with non-bundled tests): https://github.com/curl/curl/actions/runs/10980099984/job/30485440155#step:14:11 (with bundles) https://github.com/curl/curl/actions/runs/10973851013/job/30471690331#step:14:11 (w/o bundles) verbose: https://github.com/curl/curl/actions/runs/10980506956/job/30486434629#step:14:13 - with MSBuild, caused a re-evaluation of `testdeps` targets, and triggered a _rebuild_: https://github.com/curl/curl/actions/runs/10980099984/job/30485435968#step:14:19 (with bundles) https://github.com/curl/curl/actions/runs/10973851013/job/30471689714#step:14:19 (w/o bundles) verbose: https://github.com/curl/curl/actions/runs/10980506956/job/30486436368#step:14:48 It's suspected that our use of `-DCMAKE_VS_GLOBALS=TrackFileAccess=false` in CI is contributing to this. This option is supposed to affect incremental builds only. For some reason it affects CI builds too, even though they are not incremental, and no sources are changed between build steps. Reported-by: Aki Sakurai Ref: #14999 Notice that `test-*` targets depending on `testdeps` is NOT sufficient to build everything to run tests, e.g. it misses to build the curl tool, which is essential. This is also true for autotools' `test-ci` target which misses to build libcurl and the curl tool. Perhaps it'd be best to drop `testdeps` as a dependency for _all_ `test-*` targets and make it official to require building dependencies manually. Alternatively these targets could be fixed to rebuild everything necessary to run tests. Closes #15001
97 lines
3.7 KiB
CMake
97 lines
3.7 KiB
CMake
#***************************************************************************
|
|
# _ _ ____ _
|
|
# Project ___| | | | _ \| |
|
|
# / __| | | | |_) | |
|
|
# | (__| |_| | _ <| |___
|
|
# \___|\___/|_| \_\_____|
|
|
#
|
|
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
|
|
#
|
|
# This software is licensed as described in the file COPYING, which
|
|
# you should have received as part of this distribution. The terms
|
|
# are also available at https://curl.se/docs/copyright.html.
|
|
#
|
|
# You may opt to use, copy, modify, merge, publish, distribute and/or sell
|
|
# copies of the Software, and permit persons to whom the Software is
|
|
# furnished to do so, under the terms of the COPYING file.
|
|
#
|
|
# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
|
|
# KIND, either express or implied.
|
|
#
|
|
# SPDX-License-Identifier: curl
|
|
#
|
|
###########################################################################
|
|
option(CURL_TEST_BUNDLES "Bundle libtests/unittests into single binaries" OFF)
|
|
|
|
find_program(TEST_NGHTTPX "nghttpx")
|
|
if(NOT TEST_NGHTTPX)
|
|
set(TEST_NGHTTPX "nghttpx")
|
|
endif()
|
|
mark_as_advanced(TEST_NGHTTPX)
|
|
# Consumed variables: TEST_NGHTTPX
|
|
configure_file("config.in" "${CMAKE_CURRENT_BINARY_DIR}/config" @ONLY)
|
|
|
|
add_custom_target(testdeps)
|
|
add_subdirectory(http)
|
|
add_subdirectory(http/clients)
|
|
add_subdirectory(server)
|
|
add_subdirectory(libtest)
|
|
add_subdirectory(unit)
|
|
add_subdirectory(certs EXCLUDE_FROM_ALL)
|
|
|
|
function(add_runtests _targetname _test_flags)
|
|
if(CURL_TEST_BUNDLES)
|
|
set(_test_flags "${_test_flags} -bundle")
|
|
endif()
|
|
unset(_depends)
|
|
# Skip walking through dependent targets before running tests in CI.
|
|
# This avoids: GNU Make doing a slow re-evaluation of all targets and
|
|
# skipping them, MSBuild doing a re-evaluation, and actually rebuilding them.
|
|
if(NOT _targetname STREQUAL "test-ci")
|
|
set(_depends "testdeps")
|
|
endif()
|
|
# Use a special '$TFLAGS' placeholder as last argument which will be
|
|
# replaced by the contents of the environment variable in runtests.pl.
|
|
# This is a workaround for CMake's limitation where commands executed by
|
|
# 'make' or 'ninja' cannot portably reference environment variables.
|
|
string(REPLACE " " ";" _test_flags_list "${_test_flags}")
|
|
add_custom_target(${_targetname}
|
|
COMMAND
|
|
"${PERL_EXECUTABLE}" "${CMAKE_CURRENT_SOURCE_DIR}/runtests.pl"
|
|
${_test_flags_list}
|
|
"\$TFLAGS"
|
|
DEPENDS "${_depends}"
|
|
VERBATIM USES_TERMINAL
|
|
)
|
|
endfunction()
|
|
|
|
# Create configurehelp.pm, used by tests needing to run the C preprocessor.
|
|
if(MSVC OR CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang")
|
|
set(CURL_CPP "\"${CMAKE_C_COMPILER}\" -E")
|
|
if(APPLE AND CMAKE_OSX_SYSROOT)
|
|
set(CURL_CPP "${CURL_CPP} -isysroot ${CMAKE_OSX_SYSROOT}")
|
|
endif()
|
|
# Add header directories, like autotools builds do.
|
|
get_property(_include_dirs TARGET ${LIB_SELECTED} PROPERTY INCLUDE_DIRECTORIES)
|
|
foreach(_include_dir IN LISTS _include_dirs)
|
|
set(CURL_CPP "${CURL_CPP} -I${_include_dir}")
|
|
endforeach()
|
|
else()
|
|
set(CURL_CPP "cpp")
|
|
endif()
|
|
# Generate version script for the linker, for versioned symbols.
|
|
# Consumed variable:
|
|
# CURL_CPP
|
|
configure_file(
|
|
"${CMAKE_CURRENT_SOURCE_DIR}/configurehelp.pm.in"
|
|
"${CMAKE_CURRENT_BINARY_DIR}/configurehelp.pm" @ONLY)
|
|
|
|
add_runtests(test-quiet "-a -s")
|
|
add_runtests(test-am "-a -am")
|
|
add_runtests(test-full "-a -p -r")
|
|
# ~flaky means that it ignores results of tests using the flaky keyword
|
|
add_runtests(test-nonflaky "-a -p ~flaky ~timing-dependent")
|
|
add_runtests(test-ci "-a -p ~flaky ~timing-dependent -r -rm -j2")
|
|
add_runtests(test-torture "-a -t -j2")
|
|
add_runtests(test-event "-a -e")
|