mirror of
https://github.com/curl/curl.git
synced 2025-01-24 14:15:18 +08:00
2784801977
- brotli, c-ares, libpsl, libssh2, mbedtls, rustls: Use `pkg-config` for path hints and version info. Syncing them up with the rest of Find modules. - GHA/macos: force-disable libssh2 with cmake to sync with autotools. After this patch, cmake auto-detects libssh2 in this job. Closes #14545
71 lines
2.1 KiB
CMake
71 lines
2.1 KiB
CMake
#***************************************************************************
|
|
# _ _ ____ _
|
|
# Project ___| | | | _ \| |
|
|
# / __| | | | |_) | |
|
|
# | (__| |_| | _ <| |___
|
|
# \___|\___/|_| \_\_____|
|
|
#
|
|
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
|
|
#
|
|
# This software is licensed as described in the file COPYING, which
|
|
# you should have received as part of this distribution. The terms
|
|
# are also available at https://curl.se/docs/copyright.html.
|
|
#
|
|
# You may opt to use, copy, modify, merge, publish, distribute and/or sell
|
|
# copies of the Software, and permit persons to whom the Software is
|
|
# furnished to do so, under the terms of the COPYING file.
|
|
#
|
|
# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
|
|
# KIND, either express or implied.
|
|
#
|
|
# SPDX-License-Identifier: curl
|
|
#
|
|
###########################################################################
|
|
# Find the libpsl library
|
|
#
|
|
# Result Variables:
|
|
#
|
|
# LIBPSL_FOUND System has libpsl
|
|
# LIBPSL_INCLUDE_DIRS The libpsl include directories
|
|
# LIBPSL_LIBRARIES The libpsl library names
|
|
# LIBPSL_VERSION Version of libpsl
|
|
|
|
if(CURL_USE_PKGCONFIG)
|
|
find_package(PkgConfig QUIET)
|
|
pkg_search_module(PC_LIBPSL "libpsl")
|
|
endif()
|
|
|
|
find_path(LIBPSL_INCLUDE_DIR "libpsl.h"
|
|
HINTS
|
|
${PC_LIBPSL_INCLUDEDIR}
|
|
${PC_LIBPSL_INCLUDE_DIRS}
|
|
)
|
|
|
|
find_library(LIBPSL_LIBRARY NAMES "psl" "libpsl"
|
|
HINTS
|
|
${PC_LIBPSL_LIBDIR}
|
|
${PC_LIBPSL_LIBRARY_DIRS}
|
|
)
|
|
|
|
if(LIBPSL_INCLUDE_DIR)
|
|
file(STRINGS "${LIBPSL_INCLUDE_DIR}/libpsl.h" _libpsl_version_str REGEX "^#define[\t ]+PSL_VERSION[\t ]+\"(.*)\"")
|
|
string(REGEX REPLACE "^.*\"([^\"]+)\"" "\\1" LIBPSL_VERSION "${_libpsl_version_str}")
|
|
unset(_libpsl_version_str)
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(LibPSL
|
|
REQUIRED_VARS
|
|
LIBPSL_INCLUDE_DIR
|
|
LIBPSL_LIBRARY
|
|
VERSION_VAR
|
|
LIBPSL_VERSION
|
|
)
|
|
|
|
if(LIBPSL_FOUND)
|
|
set(LIBPSL_INCLUDE_DIRS ${LIBPSL_INCLUDE_DIR})
|
|
set(LIBPSL_LIBRARIES ${LIBPSL_LIBRARY})
|
|
endif()
|
|
|
|
mark_as_advanced(LIBPSL_INCLUDE_DIR LIBPSL_LIBRARY)
|