mirror of
https://github.com/curl/curl.git
synced 2025-02-17 14:59:45 +08:00
2b9b3ec579
For Find modules where `<Modulename>` is not fully uppercase. `<Modulename>` is case-exact name used in the Find modules filename: `CMake/Find<Moduleame>.cmake`. `find_package_handle_standard_args()` sets both `<MODULENAME>_FOUND` and `<Modulename>_FOUND` when detecting the dependency. Some CMake code relies on this and 3rd-party code may rely on it too. Make sure to set the latter variant when detecting the dependency via `pkg-config`, where we don't call `find_package_handle_standard_args()`. CMake sets these variable to `TRUE` (not `ON` or `1`). Replicate this for compatibility. Closes #16153
82 lines
3.0 KiB
CMake
82 lines
3.0 KiB
CMake
#***************************************************************************
|
|
# _ _ ____ _
|
|
# Project ___| | | | _ \| |
|
|
# / __| | | | |_) | |
|
|
# | (__| |_| | _ <| |___
|
|
# \___|\___/|_| \_\_____|
|
|
#
|
|
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
|
|
#
|
|
# This software is licensed as described in the file COPYING, which
|
|
# you should have received as part of this distribution. The terms
|
|
# are also available at https://curl.se/docs/copyright.html.
|
|
#
|
|
# You may opt to use, copy, modify, merge, publish, distribute and/or sell
|
|
# copies of the Software, and permit persons to whom the Software is
|
|
# furnished to do so, under the terms of the COPYING file.
|
|
#
|
|
# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
|
|
# KIND, either express or implied.
|
|
#
|
|
# SPDX-License-Identifier: curl
|
|
#
|
|
###########################################################################
|
|
# Find the brotli library
|
|
#
|
|
# Input variables:
|
|
#
|
|
# - `BROTLI_INCLUDE_DIR`: The brotli include directory.
|
|
# - `BROTLICOMMON_LIBRARY`: Path to `brotlicommon` library.
|
|
# - `BROTLIDEC_LIBRARY`: Path to `brotlidec` library.
|
|
#
|
|
# Result variables:
|
|
#
|
|
# - `BROTLI_FOUND`: System has brotli.
|
|
# - `BROTLI_INCLUDE_DIRS`: The brotli include directories.
|
|
# - `BROTLI_LIBRARIES`: The brotli library names.
|
|
# - `BROTLI_LIBRARY_DIRS`: The brotli library directories.
|
|
# - `BROTLI_PC_REQUIRES`: The brotli pkg-config packages.
|
|
# - `BROTLI_CFLAGS`: Required compiler flags.
|
|
# - `BROTLI_VERSION`: Version of brotli.
|
|
|
|
set(BROTLI_PC_REQUIRES "libbrotlidec")
|
|
|
|
if(CURL_USE_PKGCONFIG AND
|
|
NOT DEFINED BROTLI_INCLUDE_DIR AND
|
|
NOT DEFINED BROTLICOMMON_LIBRARY AND
|
|
NOT DEFINED BROTLIDEC_LIBRARY)
|
|
find_package(PkgConfig QUIET)
|
|
pkg_check_modules(BROTLI "libbrotlicommon")
|
|
pkg_check_modules(BROTLIDEC ${BROTLI_PC_REQUIRES})
|
|
endif()
|
|
|
|
if(BROTLI_FOUND AND BROTLIDEC_FOUND)
|
|
set(Brotli_FOUND TRUE)
|
|
list(APPEND BROTLIDEC_LIBRARIES ${BROTLI_LIBRARIES}) # order is significant: brotlidec then brotlicommon
|
|
list(REVERSE BROTLIDEC_LIBRARIES)
|
|
list(REMOVE_DUPLICATES BROTLIDEC_LIBRARIES)
|
|
list(REVERSE BROTLIDEC_LIBRARIES)
|
|
set(BROTLI_LIBRARIES ${BROTLIDEC_LIBRARIES})
|
|
string(REPLACE ";" " " BROTLI_CFLAGS "${BROTLI_CFLAGS}")
|
|
message(STATUS "Found Brotli (via pkg-config): ${BROTLI_INCLUDE_DIRS} (found version \"${BROTLI_VERSION}\")")
|
|
else()
|
|
find_path(BROTLI_INCLUDE_DIR "brotli/decode.h")
|
|
find_library(BROTLICOMMON_LIBRARY NAMES "brotlicommon")
|
|
find_library(BROTLIDEC_LIBRARY NAMES "brotlidec")
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(Brotli
|
|
REQUIRED_VARS
|
|
BROTLI_INCLUDE_DIR
|
|
BROTLIDEC_LIBRARY
|
|
BROTLICOMMON_LIBRARY
|
|
)
|
|
|
|
if(BROTLI_FOUND)
|
|
set(BROTLI_INCLUDE_DIRS ${BROTLI_INCLUDE_DIR})
|
|
set(BROTLI_LIBRARIES ${BROTLIDEC_LIBRARY} ${BROTLICOMMON_LIBRARY})
|
|
endif()
|
|
|
|
mark_as_advanced(BROTLI_INCLUDE_DIR BROTLIDEC_LIBRARY BROTLICOMMON_LIBRARY)
|
|
endif()
|