mirror of
https://sourceware.org/git/binutils-gdb.git
synced 2024-11-27 03:51:15 +08:00
2faa2958b5
Sync from gcc:
2005-04-22 Bernd Schmidt <bernd.schmidt@analog.com>
* config.sub: Update from master copy.
2005-04-19 Hans-Peter Nilsson <hp@axis.com>
* configure.in <crisv32-*-*, cris-*-*>: New local variable
libgcj_ex_libffi. Have specific match for *-*-linux*. Separate
matches for "*-*-aout" and "*-*-elf". Don't disable libffi for
"*-*-elf" and "*-*-linux*".
* configure: Regenerate.
config:
2005-04-29 Paolo Bonzini <bonzini@gnu.org>
* acx.m4 (ACX_PROG_GNAT): Remove stray break.
313 lines
10 KiB
Plaintext
313 lines
10 KiB
Plaintext
# Autoconf M4 include file defining utility macros for complex Canadian
|
|
# cross builds.
|
|
|
|
dnl ####
|
|
dnl # _GCC_TOPLEV_NONCANONICAL_BUILD
|
|
dnl # $build_alias or canonical $build if blank.
|
|
dnl # Used when we would use $build_alias, but empty is not OK.
|
|
AC_DEFUN([_GCC_TOPLEV_NONCANONICAL_BUILD],
|
|
[AC_REQUIRE([AC_CANONICAL_BUILD]) []dnl
|
|
case ${build_alias} in
|
|
"") build_noncanonical=${build} ;;
|
|
*) build_noncanonical=${build_alias} ;;
|
|
esac
|
|
]) []dnl # _GCC_TOPLEV_NONCANONICAL_BUILD
|
|
|
|
dnl ####
|
|
dnl # _GCC_TOPLEV_NONCANONICAL_HOST
|
|
dnl # $host_alias, or $build_noncanonical if blank.
|
|
dnl # Used when we would use $host_alias, but empty is not OK.
|
|
AC_DEFUN([_GCC_TOPLEV_NONCANONICAL_HOST],
|
|
[AC_REQUIRE([_GCC_TOPLEV_NONCANONICAL_BUILD]) []dnl
|
|
case ${host_alias} in
|
|
"") host_noncanonical=${build_noncanonical} ;;
|
|
*) host_noncanonical=${host_alias} ;;
|
|
esac
|
|
]) []dnl # _GCC_TOPLEV_NONCANONICAL_HOST
|
|
|
|
dnl ####
|
|
dnl # _GCC_TOPLEV_NONCANONICAL_TARGET
|
|
dnl # $target_alias or $host_noncanonical if blank.
|
|
dnl # Used when we would use $target_alias, but empty is not OK.
|
|
AC_DEFUN([_GCC_TOPLEV_NONCANONICAL_TARGET],
|
|
[AC_REQUIRE([_GCC_TOPLEV_NONCANONICAL_HOST]) []dnl
|
|
case ${target_alias} in
|
|
"") target_noncanonical=${host_noncanonical} ;;
|
|
*) target_noncanonical=${target_alias} ;;
|
|
esac
|
|
]) []dnl # _GCC_TOPLEV_NONCANONICAL_TARGET
|
|
|
|
dnl ####
|
|
dnl # ACX_NONCANONICAL_BUILD
|
|
dnl # Like underscored version, but AC_SUBST's.
|
|
AC_DEFUN([ACX_NONCANONICAL_BUILD],
|
|
[AC_REQUIRE([_GCC_TOPLEV_NONCANONICAL_BUILD]) []dnl
|
|
AC_SUBST(build_noncanonical)
|
|
]) []dnl # ACX_NONCANONICAL_BUILD
|
|
|
|
dnl ####
|
|
dnl # ACX_NONCANONICAL_HOST
|
|
dnl # Like underscored version, but AC_SUBST's.
|
|
AC_DEFUN([ACX_NONCANONICAL_HOST],
|
|
[AC_REQUIRE([_GCC_TOPLEV_NONCANONICAL_HOST]) []dnl
|
|
AC_SUBST(host_noncanonical)
|
|
]) []dnl # ACX_NONCANONICAL_HOST
|
|
|
|
dnl ####
|
|
dnl # ACX_NONCANONICAL_TARGET
|
|
dnl # Like underscored version, but AC_SUBST's.
|
|
AC_DEFUN([ACX_NONCANONICAL_TARGET],
|
|
[AC_REQUIRE([_GCC_TOPLEV_NONCANONICAL_TARGET]) []dnl
|
|
AC_SUBST(target_noncanonical)
|
|
]) []dnl # ACX_NONCANONICAL_TARGET
|
|
|
|
dnl ####
|
|
dnl # GCC_TOPLEV_SUBDIRS
|
|
dnl # GCC & friends build 'build', 'host', and 'target' tools. These must
|
|
dnl # be separated into three well-known subdirectories of the build directory:
|
|
dnl # build_subdir, host_subdir, and target_subdir. The values are determined
|
|
dnl # here so that they can (theoretically) be changed in the future. They
|
|
dnl # were previously reproduced across many different files.
|
|
dnl #
|
|
dnl # This logic really amounts to very little with autoconf 2.13; it will
|
|
dnl # amount to a lot more with autoconf 2.5x.
|
|
AC_DEFUN([GCC_TOPLEV_SUBDIRS],
|
|
[AC_REQUIRE([_GCC_TOPLEV_NONCANONICAL_TARGET]) []dnl
|
|
AC_REQUIRE([_GCC_TOPLEV_NONCANONICAL_BUILD]) []dnl
|
|
# Prefix 'build-' so this never conflicts with target_subdir.
|
|
build_subdir="build-${build_noncanonical}"
|
|
# --srcdir=. covers the toplevel, while "test -d" covers the subdirectories
|
|
if ( test $srcdir = . && test -d gcc ) \
|
|
|| test -d $srcdir/../host-${host_noncanonical}; then
|
|
host_subdir="host-${host_noncanonical}"
|
|
else
|
|
host_subdir=.
|
|
fi
|
|
# No prefix.
|
|
target_subdir=${target_noncanonical}
|
|
AC_SUBST([build_subdir]) []dnl
|
|
AC_SUBST([host_subdir]) []dnl
|
|
AC_SUBST([target_subdir]) []dnl
|
|
]) []dnl # GCC_TOPLEV_SUBDIRS
|
|
|
|
|
|
####
|
|
# _NCN_TOOL_PREFIXES: Some stuff that oughtta be done in AC_CANONICAL_SYSTEM
|
|
# or AC_INIT.
|
|
# These demand that AC_CANONICAL_SYSTEM be called beforehand.
|
|
AC_DEFUN([_NCN_TOOL_PREFIXES],
|
|
[ncn_tool_prefix=
|
|
test -n "$host_alias" && ncn_tool_prefix=$host_alias-
|
|
ncn_target_tool_prefix=
|
|
test -n "$target_alias" && ncn_target_tool_prefix=$target_alias-
|
|
]) []dnl # _NCN_TOOL_PREFIXES
|
|
|
|
####
|
|
# NCN_CHECK_TARGET_TOOL(variable, prog-to-check-for,[value-if-not-found],[path])
|
|
# Like AC_CHECK_TOOL, but tries a prefix of the target, not the host.
|
|
# Code is pretty much lifted from autoconf2.53.
|
|
|
|
AC_DEFUN([NCN_CHECK_TARGET_TOOL],
|
|
[AC_REQUIRE([_NCN_TOOL_PREFIXES]) []dnl
|
|
if test -n "$ncn_target_tool_prefix"; then
|
|
AC_CHECK_PROG([$1], [${ncn_target_tool_prefix}$2],
|
|
[${ncn_target_tool_prefix}$2], , [$4])
|
|
fi
|
|
if test -z "$ac_cv_prog_$1" ; then
|
|
ncn_cv_$1=$$1
|
|
AC_CHECK_PROG([ncn_cv_$1], [$2], [$2], [$3], [$4])
|
|
$1=$ncn_cv_$1
|
|
else
|
|
$1="$ac_cv_prog_$1"
|
|
fi
|
|
]) []dnl # NCN_CHECK_TARGET_TOOL
|
|
|
|
|
|
####
|
|
# NCN_STRICT_CHECK_TOOL(variable, prog-to-check-for,[value-if-not-found],[path])
|
|
# Like AC_CHECK_TOOL, but requires the prefix if build!=host.
|
|
|
|
AC_DEFUN([NCN_STRICT_CHECK_TOOL],
|
|
[AC_REQUIRE([_NCN_TOOL_PREFIXES]) []dnl
|
|
if test -n "$ncn_tool_prefix"; then
|
|
AC_CHECK_PROG([$1], [${ncn_tool_prefix}$2],
|
|
[${ncn_tool_prefix}$2], , [$4])
|
|
fi
|
|
if test -z "$ac_cv_prog_$1" ; then
|
|
if test $build = $host ; then
|
|
ncn_cv_$1=$$1
|
|
AC_CHECK_PROG([ncn_cv_$1], [$2], [$2], [ifelse([$3],[],[$2],[$3])], [$4])
|
|
$1=$ncn_cv_$1
|
|
else
|
|
$1="ifelse([$3],[],[${ncn_tool_prefix}$2],[$3])"
|
|
fi
|
|
else
|
|
$1="$ac_cv_prog_$1"
|
|
fi
|
|
]) []dnl # NCN_STRICT_CHECK_TOOL
|
|
|
|
|
|
####
|
|
# NCN_STRICT_CHECK_TARGET_TOOL(variable, prog-to-check-for,[value-if-not-found],[path])
|
|
# Like NCN_CHECK_TARGET_TOOL, but requires the prefix if build!=target.
|
|
|
|
AC_DEFUN([NCN_STRICT_CHECK_TARGET_TOOL],
|
|
[AC_REQUIRE([_NCN_TOOL_PREFIXES]) []dnl
|
|
if test -n "$ncn_target_tool_prefix"; then
|
|
AC_CHECK_PROG([$1], [${ncn_target_tool_prefix}$2],
|
|
[${ncn_target_tool_prefix}$2], , [$4])
|
|
fi
|
|
if test -z "$ac_cv_prog_$1" ; then
|
|
if test $build = $target ; then
|
|
ncn_cv_$1=$$1
|
|
AC_CHECK_PROG([ncn_cv_$1], [$2], [$2], [ifelse([$3],[],[$2],[$3])], [$4])
|
|
$1=$ncn_cv_$1
|
|
else
|
|
$1="ifelse([$3],[],[${ncn_target_tool_prefix}$2],[$3])"
|
|
fi
|
|
else
|
|
$1="$ac_cv_prog_$1"
|
|
fi
|
|
]) []dnl # NCN_STRICT_CHECK_TARGET_TOOL
|
|
|
|
###
|
|
# AC_PROG_CPP_WERROR
|
|
# Used for autoconf 2.5x to force AC_PREPROC_IFELSE to reject code which
|
|
# triggers warnings from the preprocessor. Will be in autoconf 2.58.
|
|
# For now, using this also overrides header checks to use only the
|
|
# preprocessor (matches 2.13 behavior; matching 2.58's behavior is a
|
|
# bit harder from here).
|
|
# Eventually autoconf will default to checking headers with the compiler
|
|
# instead, and we'll have to do this differently.
|
|
|
|
AC_DEFUN([AC_PROG_CPP_WERROR],
|
|
[AC_REQUIRE([AC_PROG_CPP])dnl
|
|
m4_define([AC_CHECK_HEADER],m4_defn([_AC_CHECK_HEADER_OLD]))
|
|
ac_c_preproc_warn_flag=yes])# AC_PROG_CPP_WERROR
|
|
|
|
# Test for GNAT.
|
|
# We require the gnatbind program, and a compiler driver that
|
|
# understands Ada. We use the user's CC setting, already found.
|
|
#
|
|
# Sets the shell variable have_gnat to yes or no as appropriate, and
|
|
# substitutes GNATBIND.
|
|
AC_DEFUN([ACX_PROG_GNAT],
|
|
[AC_REQUIRE([AC_CHECK_TOOL_PREFIX])
|
|
AC_REQUIRE([AC_PROG_CC])
|
|
AC_CHECK_TOOL(GNATBIND, gnatbind, no)
|
|
AC_CACHE_CHECK([whether compiler driver understands Ada],
|
|
acx_cv_cc_gcc_supports_ada,
|
|
[cat >conftest.adb <<EOF
|
|
procedure conftest is begin null; end conftest;
|
|
EOF
|
|
acx_cv_cc_gcc_supports_ada=no
|
|
# There is a bug in old released versions of GCC which causes the
|
|
# driver to exit successfully when the appropriate language module
|
|
# has not been installed. This is fixed in 2.95.4, 3.0.2, and 3.1.
|
|
# Therefore we must check for the error message as well as an
|
|
# unsuccessful exit.
|
|
# Other compilers, like HP Tru64 UNIX cc, exit successfully when
|
|
# given a .adb file, but produce no object file. So we must check
|
|
# if an object file was really produced to guard against this.
|
|
errors=`(${CC} -c conftest.adb) 2>&1 || echo failure`
|
|
if test x"$errors" = x && test -f conftest.$ac_objext; then
|
|
acx_cv_cc_gcc_supports_ada=yes
|
|
fi
|
|
rm -f conftest.*])
|
|
|
|
if test x$GNATBIND != xno && test x$acx_cv_cc_gcc_supports_ada != xno; then
|
|
have_gnat=yes
|
|
else
|
|
have_gnat=no
|
|
fi
|
|
])
|
|
|
|
dnl 'make compare' can be significantly faster, if cmp itself can
|
|
dnl skip bytes instead of using tail. The test being performed is
|
|
dnl "if cmp --ignore-initial=2 t1 t2 && ! cmp --ignore-initial=1 t1 t2"
|
|
dnl but we need to sink errors and handle broken shells. We also test
|
|
dnl for the parameter format "cmp file1 file2 skip1 skip2" which is
|
|
dnl accepted by cmp on some systems.
|
|
AC_DEFUN([ACX_PROG_CMP_IGNORE_INITIAL],
|
|
[AC_CACHE_CHECK([how to compare bootstrapped objects], gcc_cv_prog_cmp_skip,
|
|
[ echo abfoo >t1
|
|
echo cdfoo >t2
|
|
gcc_cv_prog_cmp_skip='tail +16c $$f1 > tmp-foo1; tail +16c $$f2 > tmp-foo2; cmp tmp-foo1 tmp-foo2'
|
|
if cmp t1 t2 2 2 > /dev/null 2>&1; then
|
|
if cmp t1 t2 1 1 > /dev/null 2>&1; then
|
|
:
|
|
else
|
|
gcc_cv_prog_cmp_skip='cmp $$f1 $$f2 16 16'
|
|
fi
|
|
fi
|
|
if cmp --ignore-initial=2 t1 t2 > /dev/null 2>&1; then
|
|
if cmp --ignore-initial=1 t1 t2 > /dev/null 2>&1; then
|
|
:
|
|
else
|
|
gcc_cv_prog_cmp_skip='cmp --ignore-initial=16 $$f1 $$f2'
|
|
fi
|
|
fi
|
|
rm t1 t2
|
|
])
|
|
do_compare="$gcc_cv_prog_cmp_skip"
|
|
AC_SUBST(do_compare)
|
|
])
|
|
|
|
dnl See whether we can include both string.h and strings.h.
|
|
AC_DEFUN([ACX_HEADER_STRING],
|
|
[AC_CACHE_CHECK([whether string.h and strings.h may both be included],
|
|
gcc_cv_header_string,
|
|
[AC_TRY_COMPILE([#include <string.h>
|
|
#include <strings.h>], , gcc_cv_header_string=yes, gcc_cv_header_string=no)])
|
|
if test $gcc_cv_header_string = yes; then
|
|
AC_DEFINE(STRING_WITH_STRINGS, 1, [Define if you can safely include both <string.h> and <strings.h>.])
|
|
fi
|
|
])
|
|
|
|
dnl See if stdbool.h properly defines bool and true/false.
|
|
dnl Check whether _Bool is built-in.
|
|
AC_DEFUN([ACX_HEADER_STDBOOL],
|
|
[AC_CACHE_CHECK([for working stdbool.h],
|
|
ac_cv_header_stdbool_h,
|
|
[AC_TRY_COMPILE([#include <stdbool.h>],
|
|
[bool foo = false;],
|
|
ac_cv_header_stdbool_h=yes, ac_cv_header_stdbool_h=no)])
|
|
if test $ac_cv_header_stdbool_h = yes; then
|
|
AC_DEFINE(HAVE_STDBOOL_H, 1,
|
|
[Define if you have a working <stdbool.h> header file.])
|
|
fi
|
|
AC_CACHE_CHECK(for built-in _Bool, gcc_cv_c__bool,
|
|
[AC_TRY_COMPILE(,
|
|
[_Bool foo;],
|
|
gcc_cv_c__bool=yes, gcc_cv_c__bool=no)
|
|
])
|
|
if test $gcc_cv_c__bool = yes; then
|
|
AC_DEFINE(HAVE__BOOL, 1, [Define if the \`_Bool' type is built-in.])
|
|
fi
|
|
])
|
|
|
|
dnl See if hard links work and if not, try to substitute $1 or simple copy.
|
|
AC_DEFUN([ACX_PROG_LN],
|
|
[AC_MSG_CHECKING(whether ln works)
|
|
AC_CACHE_VAL(acx_cv_prog_LN,
|
|
[rm -f conftestdata_t
|
|
echo >conftestdata_f
|
|
if ln conftestdata_f conftestdata_t 2>/dev/null
|
|
then
|
|
acx_cv_prog_LN=ln
|
|
else
|
|
acx_cv_prog_LN=no
|
|
fi
|
|
rm -f conftestdata_f conftestdata_t
|
|
])dnl
|
|
if test $acx_cv_prog_LN = no; then
|
|
LN="ifelse([$1],,cp,[$1])"
|
|
AC_MSG_RESULT([no, using $LN])
|
|
else
|
|
LN="$acx_cv_prog_LN"
|
|
AC_MSG_RESULT(yes)
|
|
fi
|
|
AC_SUBST(LN)dnl
|
|
])
|
|
|