mirror of
https://sourceware.org/git/binutils-gdb.git
synced 2025-03-07 13:39:43 +08:00
73cc72729a
This patch moves the gdb/gnulib subdirectory to the top level. It adjusts the top-level build system to build gnulib when necessary, and changes gdb to use this. However, gdbserver still builds its own copy of gnulib, just from the new source location. A small hack was needed to ensure that gnulib is only built when gdb is enabled. The Makefile only provides an ordering -- the directory must be mentioned in configdirs to actually be compiled at all. Most of the patch is just a "git mv" of gnulib, though a few minor path adjustments were needed in some files there. Tested by the buildbot. ChangeLog 2019-06-14 Tom Tromey <tom@tromey.com> * MAINTAINERS: Add gnulib. * gnulib: New directory, move from gdb/gnulib. * configure.ac (host_libs): Add gnulib. * configure: Rebuild. * Makefile.def (host_modules, dependencies): Add gnulib. * Makefile.in: Rebuild. gdb/ChangeLog 2019-06-14 Tom Tromey <tom@tromey.com> * gnulib: Move directory to top-level. * configure.ac: Don't configure gnulib. * configure: Rebuild. * common/common-defs.h: Use new path to gnulib. * Makefile.in (GNULIB_BUILDDIR): Now ../gnulib. (GNULIB_H): Remove. (INCGNU): Look in new gnulib location. (HFILES_NO_SRCDIR): Remove gnulib files. (SUBDIR, REQUIRED_SUBDIRS): Remove gnulib. (generated_files): Remove GNULIB_H. ($(LIBGNU), all-lib): Remove targets. (distclean): Don't mention GNULIB_BUILDDIR. ($(GNULIB_BUILDDIR)/Makefile): Remove target. gdb/gdbserver/ChangeLog 2019-06-14 Tom Tromey <tom@tromey.com> * configure.ac: Use new path to gnulib. * configure: Rebuild. * Makefile.in (INCGNU, $(GNULIB_BUILDDIR)/Makefile): Use new path to gnulib. gnulib/ChangeLog 2019-06-14 Tom Tromey <tom@tromey.com> * update-gnulib.sh: Adjust paths. * Makefile.in: Adjust paths. * configure.ac: Adjust paths. Use ACX_LARGEFILE. * configure: Rebuild.
46 lines
1.3 KiB
Plaintext
46 lines
1.3 KiB
Plaintext
# dup.m4 serial 4
|
|
dnl Copyright (C) 2011-2016 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
AC_DEFUN([gl_FUNC_DUP],
|
|
[
|
|
AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
|
|
AC_REQUIRE([gl_MSVC_INVAL])
|
|
if test $HAVE_MSVC_INVALID_PARAMETER_HANDLER = 1; then
|
|
REPLACE_DUP=1
|
|
fi
|
|
dnl Replace dup() for supporting the gnulib-defined fchdir() function,
|
|
dnl to keep fchdir's bookkeeping up-to-date.
|
|
m4_ifdef([gl_FUNC_FCHDIR], [
|
|
gl_TEST_FCHDIR
|
|
if test $HAVE_FCHDIR = 0; then
|
|
REPLACE_DUP=1
|
|
fi
|
|
])
|
|
AC_CACHE_CHECK([whether dup works], [gl_cv_func_dup_works],
|
|
[AC_RUN_IFELSE(
|
|
[AC_LANG_PROGRAM([[#include <unistd.h>
|
|
#include <fcntl.h>
|
|
#include <errno.h>]],
|
|
[[/* On OS/2 kLIBC, dup does not work on a directory fd. */
|
|
int fd = open (".", O_RDONLY);
|
|
return fd < 0 ? 1 : dup (fd) < 0 ? 2 : 0;
|
|
]])
|
|
],
|
|
[gl_cv_func_dup_works=yes],
|
|
[gl_cv_func_dup_works=no],
|
|
[gl_cv_func_dup_works='guessing yes'])
|
|
])
|
|
case "$gl_cv_func_dup_works" in
|
|
*yes) ;;
|
|
*)
|
|
REPLACE_DUP=1
|
|
;;
|
|
esac
|
|
])
|
|
|
|
# Prerequisites of lib/dup.c.
|
|
AC_DEFUN([gl_PREREQ_DUP], [:])
|