mirror of
https://sourceware.org/git/binutils-gdb.git
synced 2024-12-03 04:12:10 +08:00
69ad8cac12
* Makefile.am: Rebuild dependencies. (CFILES): Add vax-dis.c. (ALL_MACHINES): Add vax-dis.lo. * aclocal.m4: Rebuild with current libtool. * configure, Makefile.in: Rebuild. Fri Jun 26 12:03:20 1998 Klaus Kaempf <kkaempf@progis.de> * vax-dis.c: New file, from work by Pauline Middelink <middelin@polyware.iaf.nl>. * disassemble.c (ARCH_vax): Define if ARCH_all. (disassembler): Add case for ARCH_vax. * makefile.vms: Support compilation on vms/vax.
239 lines
6.2 KiB
Plaintext
239 lines
6.2 KiB
Plaintext
dnl Process this file with autoconf to produce a configure script.
|
|
dnl
|
|
|
|
AC_PREREQ(2.5)
|
|
AC_INIT(z8k-dis.c)
|
|
|
|
AC_CANONICAL_SYSTEM
|
|
AC_ISC_POSIX
|
|
|
|
# We currently only use the version number for the name of any shared
|
|
# library. For user convenience, we always use the same version
|
|
# number that BFD is using.
|
|
changequote(,)dnl
|
|
BFD_VERSION=`grep INIT_AUTOMAKE ${srcdir}/../bfd/configure.in | sed -n -e 's/[ ]//g' -e 's/^.*,\(.*\)).*$/\1/p'`
|
|
changequote([,])dnl
|
|
|
|
AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION})
|
|
|
|
dnl These must be called before AM_PROG_LIBTOOL, because it may want
|
|
dnl to call AC_CHECK_PROG.
|
|
AC_CHECK_TOOL(AR, ar)
|
|
AC_CHECK_TOOL(RANLIB, ranlib, :)
|
|
|
|
dnl Default to a non shared library. This may be overridden by the
|
|
dnl configure option --enable-shared.
|
|
AM_DISABLE_SHARED
|
|
|
|
AM_PROG_LIBTOOL
|
|
|
|
AC_ARG_ENABLE(targets,
|
|
[ --enable-targets alternative target configurations],
|
|
[case "${enableval}" in
|
|
yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
|
|
;;
|
|
no) enable_targets= ;;
|
|
*) enable_targets=$enableval ;;
|
|
esac])dnl
|
|
AC_ARG_ENABLE(commonbfdlib,
|
|
[ --enable-commonbfdlib build shared BFD/opcodes/libiberty library],
|
|
[case "${enableval}" in
|
|
yes) commonbfdlib=true ;;
|
|
no) commonbfdlib=false ;;
|
|
*) AC_MSG_ERROR([bad value ${enableval} for opcodes commonbfdlib option]) ;;
|
|
esac])dnl
|
|
|
|
AM_CONFIG_HEADER(config.h:config.in)
|
|
|
|
if test -z "$target" ; then
|
|
AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
|
|
fi
|
|
AC_ARG_PROGRAM
|
|
|
|
AM_MAINTAINER_MODE
|
|
AM_CYGWIN32
|
|
AM_EXEEXT
|
|
|
|
# host-specific stuff:
|
|
|
|
AC_PROG_CC
|
|
|
|
ALL_LINGUAS=
|
|
CY_GNU_GETTEXT
|
|
|
|
. ${srcdir}/../bfd/configure.host
|
|
|
|
AC_SUBST(HDEFINES)
|
|
AM_PROG_INSTALL
|
|
|
|
AC_CHECK_HEADERS(string.h strings.h stdlib.h)
|
|
|
|
# start-sanitize-cygnus
|
|
use_cgen=no
|
|
cgen_maint=no
|
|
# Having --enable-maintainer-mode take arguments is another way to go.
|
|
AC_ARG_ENABLE(cgen-maint,
|
|
[ --enable-cgen-maint build cgen generated files],
|
|
[case "${enableval}" in
|
|
yes) cgen_maint=yes ;;
|
|
no) cgen_maint=no ;;
|
|
*) AC_MSG_ERROR([bad value ${enableval} for opcodes cgen-maint option]) ;;
|
|
esac])dnl
|
|
AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
|
|
if test "x${cgen_maint}" = xyes ; then
|
|
for targ in $target $canon_targets
|
|
do
|
|
case $targ in
|
|
all) use_cgen=yes ;;
|
|
m32r-*-*) use_cgen=yes ;;
|
|
esac
|
|
done
|
|
fi
|
|
if test $use_cgen = yes ; then
|
|
AC_CHECK_PROG(SCHEME, guile, guile, guile)
|
|
fi
|
|
# end-sanitize-cygnus
|
|
|
|
# Horrible hacks to build DLLs on Windows.
|
|
WIN32LDFLAGS=
|
|
WIN32LIBADD=
|
|
case "${host}" in
|
|
*-*-cygwin32*)
|
|
if test "$enable_shared" = "yes"; then
|
|
WIN32LDFLAGS="-no-undefined"
|
|
WIN32LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
|
|
fi
|
|
;;
|
|
esac
|
|
AC_SUBST(WIN32LDFLAGS)
|
|
AC_SUBST(WIN32LIBADD)
|
|
|
|
# target-specific stuff:
|
|
|
|
# Canonicalize the secondary target names.
|
|
if test -n "$enable_targets" ; then
|
|
for targ in `echo $enable_targets | sed 's/,/ /g'`
|
|
do
|
|
result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ 2>/dev/null`
|
|
if test -n "$result" ; then
|
|
canon_targets="$canon_targets $result"
|
|
else
|
|
# Allow targets that config.sub doesn't recognize, like "all".
|
|
canon_targets="$canon_targets $targ"
|
|
fi
|
|
done
|
|
fi
|
|
|
|
all_targets=false
|
|
selarchs=
|
|
for targ in $target $canon_targets
|
|
do
|
|
if test "x$targ" = "xall" ; then
|
|
all_targets=true
|
|
else
|
|
. $srcdir/../bfd/config.bfd
|
|
selarchs="$selarchs $targ_archs"
|
|
fi
|
|
done
|
|
|
|
# Utility var, documents generic cgen support files.
|
|
|
|
cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo"
|
|
|
|
# We don't do any links based on the target system, just makefile config.
|
|
|
|
if test x${all_targets} = xfalse ; then
|
|
|
|
# Target architecture .o files.
|
|
ta=
|
|
|
|
for arch in $selarchs
|
|
do
|
|
ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
|
|
archdefs="$archdefs -DARCH_$ad"
|
|
case "$arch" in
|
|
bfd_a29k_arch) ta="$ta a29k-dis.lo" ;;
|
|
bfd_alliant_arch) ;;
|
|
bfd_alpha_arch) ta="$ta alpha-dis.lo alpha-opc.lo" ;;
|
|
bfd_arc_arch) ta="$ta arc-dis.lo arc-opc.lo" ;;
|
|
bfd_arm_arch) ta="$ta arm-dis.lo" ;;
|
|
bfd_convex_arch) ;;
|
|
bfd_d10v_arch) ta="$ta d10v-dis.lo d10v-opc.lo" ;;
|
|
# start-sanitize-d30v
|
|
bfd_d30v_arch) ta="$ta d30v-dis.lo d30v-opc.lo" ;;
|
|
# end-sanitize-d30v
|
|
bfd_h8300_arch) ta="$ta h8300-dis.lo" ;;
|
|
bfd_h8500_arch) ta="$ta h8500-dis.lo" ;;
|
|
bfd_hppa_arch) ta="$ta hppa-dis.lo" ;;
|
|
bfd_i386_arch) ta="$ta i386-dis.lo" ;;
|
|
bfd_i860_arch) ;;
|
|
bfd_i960_arch) ta="$ta i960-dis.lo" ;;
|
|
bfd_m32r_arch) ta="$ta $cgen_files m32r-opc.lo m32r-asm.lo m32r-dis.lo" ;;
|
|
bfd_m68k_arch) ta="$ta m68k-dis.lo m68k-opc.lo" ;;
|
|
bfd_m88k_arch) ta="$ta m88k-dis.lo" ;;
|
|
bfd_mips_arch) ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo" ;;
|
|
bfd_mn10200_arch) ta="$ta m10200-dis.lo m10200-opc.lo" ;;
|
|
bfd_mn10300_arch) ta="$ta m10300-dis.lo m10300-opc.lo" ;;
|
|
bfd_ns32k_arch) ta="$ta ns32k-dis.lo" ;;
|
|
bfd_powerpc_arch) ta="$ta ppc-dis.lo ppc-opc.lo" ;;
|
|
bfd_pyramid_arch) ;;
|
|
bfd_romp_arch) ;;
|
|
bfd_rs6000_arch) ta="$ta ppc-dis.lo ppc-opc.lo" ;;
|
|
bfd_sh_arch) ta="$ta sh-dis.lo" ;;
|
|
bfd_sparc_arch) ta="$ta sparc-dis.lo sparc-opc.lo" ;;
|
|
bfd_tahoe_arch) ;;
|
|
bfd_tic30_arch) ta="$ta tic30-dis.lo" ;;
|
|
# start-sanitize-tic80
|
|
bfd_tic80_arch) ta="$ta tic80-dis.lo tic80-opc.lo" ;;
|
|
# end-sanitize-tic80
|
|
# start-sanitize-sky
|
|
bfd_dvp_arch) ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo dvp-dis.lo dvp-opc.lo" ;;
|
|
# end-sanitize-sky
|
|
bfd_v850_arch) ta="$ta v850-opc.lo v850-dis.lo" ;;
|
|
# start-sanitize-v850e
|
|
bfd_v850e_arch) ta="$ta v850-opc.lo v850-dis.lo" ;;
|
|
bfd_v850ea_arch) ta="$ta v850-opc.lo v850-dis.lo" ;;
|
|
# end-sanitize-v850e
|
|
bfd_vax_arch) ta="$ta vax-dis.lo" ;;
|
|
bfd_w65_arch) ta="$ta w65-dis.lo" ;;
|
|
bfd_we32k_arch) ;;
|
|
bfd_z8k_arch) ta="$ta z8k-dis.lo" ;;
|
|
|
|
"") ;;
|
|
*) AC_MSG_ERROR(*** unknown target architecture $arch) ;;
|
|
esac
|
|
done
|
|
|
|
# Weed out duplicate .o files.
|
|
f=""
|
|
for i in $ta ; do
|
|
case " $f " in
|
|
*" $i "*) ;;
|
|
*) f="$f $i" ;;
|
|
esac
|
|
done
|
|
ta="$f"
|
|
|
|
# And duplicate -D flags.
|
|
f=""
|
|
for i in $archdefs ; do
|
|
case " $f " in
|
|
*" $i "*) ;;
|
|
*) f="$f $i" ;;
|
|
esac
|
|
done
|
|
archdefs="$f"
|
|
|
|
BFD_MACHINES="$ta"
|
|
|
|
else # all_targets is true
|
|
archdefs=-DARCH_all
|
|
BFD_MACHINES='$(ALL_MACHINES)'
|
|
fi
|
|
|
|
AC_SUBST(archdefs)
|
|
AC_SUBST(BFD_MACHINES)
|
|
|
|
AC_OUTPUT(Makefile po/Makefile.in:po/Make-in,
|
|
[sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])
|