mirror of
git://git.sv.gnu.org/autoconf
synced 2025-02-17 14:01:27 +08:00
9b939481e6
* ChangeLog, GNUmakefile, build-aux/announce-gen: * build-aux/config.guess, build-aux/config.sub, build-aux/gendocs.sh: * build-aux/git-version-gen, build-aux/move-if-change: * build-aux/texinfo.tex, build-aux/update-copyright: * build-aux/vc-list-files, doc/fdl.texi, doc/gendocs_template: * doc/standards.texi, lib/Autom4te/XFile.pm, m4/autobuild.m4: Regenerated by 'make fetch'.
40 lines
1.0 KiB
Plaintext
40 lines
1.0 KiB
Plaintext
# autobuild.m4 serial 7
|
|
dnl Copyright (C) 2004, 2006-2011 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl From Simon Josefsson
|
|
|
|
# Usage: AB_INIT([MODE]).
|
|
AC_DEFUN([AB_INIT],
|
|
[
|
|
AC_REQUIRE([AC_CANONICAL_BUILD])
|
|
AC_REQUIRE([AC_CANONICAL_HOST])
|
|
|
|
if test -z "$AB_PACKAGE"; then
|
|
AB_PACKAGE=${PACKAGE_NAME:-$PACKAGE}
|
|
fi
|
|
AC_MSG_NOTICE([autobuild project... $AB_PACKAGE])
|
|
|
|
if test -z "$AB_VERSION"; then
|
|
AB_VERSION=${PACKAGE_VERSION:-$VERSION}
|
|
fi
|
|
AC_MSG_NOTICE([autobuild revision... $AB_VERSION])
|
|
|
|
hostname=`hostname`
|
|
if test "$hostname"; then
|
|
AC_MSG_NOTICE([autobuild hostname... $hostname])
|
|
fi
|
|
|
|
ifelse([$1],[],,[AC_MSG_NOTICE([autobuild mode... $1])])
|
|
|
|
date=`TZ=UTC0 date +%Y%m%dT%H%M%SZ`
|
|
if test "$?" != 0; then
|
|
date=`date`
|
|
fi
|
|
if test "$date"; then
|
|
AC_MSG_NOTICE([autobuild timestamp... $date])
|
|
fi
|
|
])
|