mirror of
git://git.sv.gnu.org/autoconf
synced 2025-02-17 14:01:27 +08:00
Add.
This commit is contained in:
Akim Demaille
parent
23126e8683
commit
5c291bb921
@ -4,7 +4,6 @@
|
||||
AC_TRY_COMMAND.
|
||||
(AC_DECL_YYTEXT): Fix the previous patch: it points to AC_PROG_LEX.
|
||||
|
||||
|
||||
2001-08-22 Akim Demaille <akim@epita.fr>
|
||||
|
||||
* lib/autoconf/general.m4 (AC_SHELL_PATH_WALK, AC_CHECK_PROG)
|
||||
@ -20,7 +19,6 @@
|
||||
* lib/autoconf/autoconf.m4, lib/autoconf/Makefile.am
|
||||
* tests/Makefile.am, tests/suite.am: Adjust.
|
||||
|
||||
|
||||
2001-08-22 Akim Demaille <akim@epita.fr>
|
||||
|
||||
* lib/autoconf/general.m4 (AC_LIST_MEMBER_OF, AC_LINKER_OPTION):
|
||||
|
||||
486
lib/autoconf/libs.m4
Normal file
486
lib/autoconf/libs.m4
Normal file
@ -0,0 +1,486 @@
|
||||
# This file is part of Autoconf. -*- Autoconf -*-
|
||||
# Checking for libraries.
|
||||
# Copyright 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000, 2001
|
||||
# Free Software Foundation, Inc.
|
||||
|
||||
# This program is free software; you can redistribute it and/or modify
|
||||
# it under the terms of the GNU General Public License as published by
|
||||
# the Free Software Foundation; either version 2, or (at your option)
|
||||
# any later version.
|
||||
#
|
||||
# This program is distributed in the hope that it will be useful,
|
||||
# but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||||
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||||
# GNU General Public License for more details.
|
||||
#
|
||||
# You should have received a copy of the GNU General Public License
|
||||
# along with this program; if not, write to the Free Software
|
||||
# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
|
||||
# 02111-1307, USA.
|
||||
|
||||
# As a special exception, the Free Software Foundation gives unlimited
|
||||
# permission to copy, distribute and modify the configure scripts that
|
||||
# are the output of Autoconf. You need not follow the terms of the GNU
|
||||
# General Public License when using or distributing such scripts, even
|
||||
# though portions of the text of Autoconf appear in them. The GNU
|
||||
# General Public License (GPL) does govern all other use of the material
|
||||
# that constitutes the Autoconf program.
|
||||
#
|
||||
# Certain portions of the Autoconf source text are designed to be copied
|
||||
# (in certain cases, depending on the input) into the output of
|
||||
# Autoconf. We call these the "data" portions. The rest of the Autoconf
|
||||
# source text consists of comments plus executable code that decides which
|
||||
# of the data portions to output in any given case. We call these
|
||||
# comments and executable code the "non-data" portions. Autoconf never
|
||||
# copies any of the non-data portions into its output.
|
||||
#
|
||||
# This special exception to the GPL applies to versions of Autoconf
|
||||
# released by the Free Software Foundation. When you make and
|
||||
# distribute a modified version of Autoconf, you may extend this special
|
||||
# exception to the GPL to apply to your modified version as well, *unless*
|
||||
# your modified version has the potential to copy into its output some
|
||||
# of the text that was the non-data portion of the version that you started
|
||||
# with. (In other words, unless your change moves or copies text from
|
||||
# the non-data portions to the data portions.) If your modification has
|
||||
# such potential, you must delete any notice of this special exception
|
||||
# to the GPL from your modified version.
|
||||
#
|
||||
# Written by David MacKenzie, with help from
|
||||
# Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
|
||||
# Roland McGrath, Noah Friedman, david d zuhn, and many others.
|
||||
|
||||
# Table of contents
|
||||
#
|
||||
# 1. Generic tests for libraries
|
||||
# 2. Tests for specific libraires
|
||||
|
||||
|
||||
## --------------------------------- ##
|
||||
## 1. Generic tests for libraires.## ##
|
||||
## --------------------------------- ##
|
||||
|
||||
|
||||
|
||||
# AC_SEARCH_LIBS(FUNCTION, SEARCH-LIBS,
|
||||
# [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND],
|
||||
# [OTHER-LIBRARIES])
|
||||
# --------------------------------------------------------
|
||||
# Search for a library defining FUNC, if it's not already available.
|
||||
AC_DEFUN([AC_SEARCH_LIBS],
|
||||
[AC_CACHE_CHECK([for library containing $1], [ac_cv_search_$1],
|
||||
[ac_func_search_save_LIBS=$LIBS
|
||||
ac_cv_search_$1=no
|
||||
AC_TRY_LINK_FUNC([$1], [ac_cv_search_$1="none required"])
|
||||
if test "$ac_cv_search_$1" = no; then
|
||||
for ac_lib in $2; do
|
||||
LIBS="-l$ac_lib $5 $ac_func_search_save_LIBS"
|
||||
AC_TRY_LINK_FUNC([$1],
|
||||
[ac_cv_search_$1="-l$ac_lib"
|
||||
break])
|
||||
done
|
||||
fi
|
||||
LIBS=$ac_func_search_save_LIBS])
|
||||
AS_IF([test "$ac_cv_search_$1" != no],
|
||||
[test "$ac_cv_search_$1" = "none required" || LIBS="$ac_cv_search_$1 $LIBS"
|
||||
$3],
|
||||
[$4])dnl
|
||||
])
|
||||
|
||||
|
||||
|
||||
# AC_CHECK_LIB(LIBRARY, FUNCTION,
|
||||
# [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND],
|
||||
# [OTHER-LIBRARIES])
|
||||
# ------------------------------------------------------
|
||||
#
|
||||
# Use a cache variable name containing both the library and function name,
|
||||
# because the test really is for library $1 defining function $2, not
|
||||
# just for library $1. Separate tests with the same $1 and different $2s
|
||||
# may have different results.
|
||||
#
|
||||
# Note that using directly AS_VAR_PUSHDEF([ac_Lib], [ac_cv_lib_$1_$2])
|
||||
# is asking for troubles, since AC_CHECK_LIB($lib, fun) would give
|
||||
# ac_cv_lib_$lib_fun, which is definitely not what was meant. Hence
|
||||
# the AS_LITERAL_IF indirection.
|
||||
#
|
||||
# FIXME: This macro is extremely suspicious. It DEFINEs unconditionnally,
|
||||
# whatever the FUNCTION, in addition to not being a *S macro. Note
|
||||
# that the cache does depend upon the function we are looking for.
|
||||
#
|
||||
# It is on purpose we used `ac_check_lib_save_LIBS' and not just
|
||||
# `ac_save_LIBS': there are many macros which don't want to see `LIBS'
|
||||
# changed but still want to use AC_CHECK_LIB, so they save `LIBS'.
|
||||
# And ``ac_save_LIBS' is too tempting a name, so let's leave them some
|
||||
# freedom.
|
||||
AC_DEFUN([AC_CHECK_LIB],
|
||||
[m4_ifval([$3], , [AH_CHECK_LIB([$1])])dnl
|
||||
AS_LITERAL_IF([$1],
|
||||
[AS_VAR_PUSHDEF([ac_Lib], [ac_cv_lib_$1_$2])],
|
||||
[AS_VAR_PUSHDEF([ac_Lib], [ac_cv_lib_$1''_$2])])dnl
|
||||
AC_CACHE_CHECK([for $2 in -l$1], ac_Lib,
|
||||
[ac_check_lib_save_LIBS=$LIBS
|
||||
LIBS="-l$1 $5 $LIBS"
|
||||
AC_TRY_LINK_FUNC([$2],
|
||||
[AS_VAR_SET(ac_Lib, yes)],
|
||||
[AS_VAR_SET(ac_Lib, no)])
|
||||
LIBS=$ac_check_lib_save_LIBS])
|
||||
AS_IF([test AS_VAR_GET(ac_Lib) = yes],
|
||||
[m4_default([$3], [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_LIB$1))
|
||||
LIBS="-l$1 $LIBS"
|
||||
])],
|
||||
[$4])dnl
|
||||
AS_VAR_POPDEF([ac_Lib])dnl
|
||||
])# AC_CHECK_LIB
|
||||
|
||||
|
||||
# AH_CHECK_LIB(LIBNAME)
|
||||
# ---------------------
|
||||
m4_define([AH_CHECK_LIB],
|
||||
[AH_TEMPLATE(AS_TR_CPP(HAVE_LIB$1),
|
||||
[Define if you have the `]$1[' library (-l]$1[).])])
|
||||
|
||||
|
||||
# AC_HAVE_LIBRARY(LIBRARY,
|
||||
# [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND],
|
||||
# [OTHER-LIBRARIES])
|
||||
# ---------------------------------------------------------
|
||||
#
|
||||
# This macro is equivalent to calling `AC_CHECK_LIB' with a FUNCTION
|
||||
# argument of `main'. In addition, LIBRARY can be written as any of
|
||||
# `foo', `-lfoo', or `libfoo.a'. In all of those cases, the compiler
|
||||
# is passed `-lfoo'. However, LIBRARY cannot be a shell variable;
|
||||
# it must be a literal name.
|
||||
AU_DEFUN([AC_HAVE_LIBRARY],
|
||||
[m4_pushdef([AC_Lib_Name],
|
||||
m4_patsubst(m4_patsubst([[$1]],
|
||||
[lib\([^\.]*\)\.a], [\1]),
|
||||
[-l], []))dnl
|
||||
AC_CHECK_LIB(AC_Lib_Name, main, [$2], [$3], [$4])dnl
|
||||
ac_cv_lib_[]AC_Lib_Name()=ac_cv_lib_[]AC_Lib_Name()_main
|
||||
m4_popdef([AC_Lib_Name])dnl
|
||||
])
|
||||
|
||||
|
||||
|
||||
|
||||
## --------------------------------- ##
|
||||
## 2. Tests for specific libraries. ##
|
||||
## --------------------------------- ##
|
||||
|
||||
|
||||
|
||||
# --------------------- #
|
||||
# Checks for X window. #
|
||||
# --------------------- #
|
||||
|
||||
|
||||
# _AC_PATH_X_XMKMF
|
||||
# ----------------
|
||||
# Internal subroutine of _AC_PATH_X.
|
||||
# Set ac_x_includes and/or ac_x_libraries.
|
||||
m4_define([_AC_PATH_X_XMKMF],
|
||||
[rm -fr conftest.dir
|
||||
if mkdir conftest.dir; then
|
||||
cd conftest.dir
|
||||
# Make sure to not put "make" in the Imakefile rules, since we grep it out.
|
||||
cat >Imakefile <<'_ACEOF'
|
||||
acfindx:
|
||||
@echo 'ac_im_incroot="${INCROOT}"; ac_im_usrlibdir="${USRLIBDIR}"; ac_im_libdir="${LIBDIR}"'
|
||||
_ACEOF
|
||||
if (xmkmf) >/dev/null 2>/dev/null && test -f Makefile; then
|
||||
# GNU make sometimes prints "make[1]: Entering...", which would confuse us.
|
||||
eval `${MAKE-make} acfindx 2>/dev/null | grep -v make`
|
||||
# Open Windows xmkmf reportedly sets LIBDIR instead of USRLIBDIR.
|
||||
for ac_extension in a so sl; do
|
||||
if test ! -f $ac_im_usrlibdir/libX11.$ac_extension &&
|
||||
test -f $ac_im_libdir/libX11.$ac_extension; then
|
||||
ac_im_usrlibdir=$ac_im_libdir; break
|
||||
fi
|
||||
done
|
||||
# Screen out bogus values from the imake configuration. They are
|
||||
# bogus both because they are the default anyway, and because
|
||||
# using them would break gcc on systems where it needs fixed includes.
|
||||
case $ac_im_incroot in
|
||||
/usr/include) ;;
|
||||
*) test -f "$ac_im_incroot/X11/Xos.h" && ac_x_includes=$ac_im_incroot;;
|
||||
esac
|
||||
case $ac_im_usrlibdir in
|
||||
/usr/lib | /lib) ;;
|
||||
*) test -d "$ac_im_usrlibdir" && ac_x_libraries=$ac_im_usrlibdir ;;
|
||||
esac
|
||||
fi
|
||||
cd ..
|
||||
rm -fr conftest.dir
|
||||
fi
|
||||
])# _AC_PATH_X_XMKMF
|
||||
|
||||
|
||||
# _AC_PATH_X_DIRECT
|
||||
# -----------------
|
||||
# Internal subroutine of _AC_PATH_X.
|
||||
# Set ac_x_includes and/or ac_x_libraries.
|
||||
m4_define([_AC_PATH_X_DIRECT],
|
||||
[# Standard set of common directories for X headers.
|
||||
# Check X11 before X11Rn because it is often a symlink to the current release.
|
||||
ac_x_header_dirs='
|
||||
/usr/X11/include
|
||||
/usr/X11R6/include
|
||||
/usr/X11R5/include
|
||||
/usr/X11R4/include
|
||||
|
||||
/usr/include/X11
|
||||
/usr/include/X11R6
|
||||
/usr/include/X11R5
|
||||
/usr/include/X11R4
|
||||
|
||||
/usr/local/X11/include
|
||||
/usr/local/X11R6/include
|
||||
/usr/local/X11R5/include
|
||||
/usr/local/X11R4/include
|
||||
|
||||
/usr/local/include/X11
|
||||
/usr/local/include/X11R6
|
||||
/usr/local/include/X11R5
|
||||
/usr/local/include/X11R4
|
||||
|
||||
/usr/X386/include
|
||||
/usr/x386/include
|
||||
/usr/XFree86/include/X11
|
||||
|
||||
/usr/include
|
||||
/usr/local/include
|
||||
/usr/unsupported/include
|
||||
/usr/athena/include
|
||||
/usr/local/x11r5/include
|
||||
/usr/lpp/Xamples/include
|
||||
|
||||
/usr/openwin/include
|
||||
/usr/openwin/share/include'
|
||||
|
||||
if test "$ac_x_includes" = no; then
|
||||
# Guess where to find include files, by looking for Intrinsic.h.
|
||||
# First, try using that file with no special directory specified.
|
||||
AC_PREPROC_IFELSE([AC_LANG_SOURCE([@%:@include <X11/Intrinsic.h>])],
|
||||
[# We can compile using X headers with no special include directory.
|
||||
ac_x_includes=],
|
||||
[for ac_dir in $ac_x_header_dirs; do
|
||||
if test -r "$ac_dir/X11/Intrinsic.h"; then
|
||||
ac_x_includes=$ac_dir
|
||||
break
|
||||
fi
|
||||
done])
|
||||
fi # $ac_x_includes = no
|
||||
|
||||
if test "$ac_x_libraries" = no; then
|
||||
# Check for the libraries.
|
||||
# See if we find them without any special options.
|
||||
# Don't add to $LIBS permanently.
|
||||
ac_save_LIBS=$LIBS
|
||||
LIBS="-lXt $LIBS"
|
||||
AC_TRY_LINK([@%:@include <X11/Intrinsic.h>], [XtMalloc (0)],
|
||||
[LIBS=$ac_save_LIBS
|
||||
# We can link X programs with no special library path.
|
||||
ac_x_libraries=],
|
||||
[LIBS=$ac_save_LIBS
|
||||
for ac_dir in `echo "$ac_x_includes $ac_x_header_dirs" | sed s/include/lib/g`
|
||||
do
|
||||
# Don't even attempt the hair of trying to link an X program!
|
||||
for ac_extension in a so sl; do
|
||||
if test -r $ac_dir/libXt.$ac_extension; then
|
||||
ac_x_libraries=$ac_dir
|
||||
break 2
|
||||
fi
|
||||
done
|
||||
done])
|
||||
fi # $ac_x_libraries = no
|
||||
])# _AC_PATH_X_DIRECT
|
||||
|
||||
|
||||
# _AC_PATH_X
|
||||
# ----------
|
||||
# Compute ac_cv_have_x.
|
||||
AC_DEFUN([_AC_PATH_X],
|
||||
[AC_CACHE_VAL(ac_cv_have_x,
|
||||
[# One or both of the vars are not set, and there is no cached value.
|
||||
ac_x_includes=no ac_x_libraries=no
|
||||
_AC_PATH_X_XMKMF
|
||||
_AC_PATH_X_DIRECT
|
||||
if test "$ac_x_includes" = no || test "$ac_x_libraries" = no; then
|
||||
# Didn't find X anywhere. Cache the known absence of X.
|
||||
ac_cv_have_x="have_x=no"
|
||||
else
|
||||
# Record where we found X for the cache.
|
||||
ac_cv_have_x="have_x=yes \
|
||||
ac_x_includes=$ac_x_includes ac_x_libraries=$ac_x_libraries"
|
||||
fi])dnl
|
||||
])
|
||||
|
||||
|
||||
# AC_PATH_X
|
||||
# ---------
|
||||
# If we find X, set shell vars x_includes and x_libraries to the
|
||||
# paths, otherwise set no_x=yes.
|
||||
# Uses ac_ vars as temps to allow command line to override cache and checks.
|
||||
# --without-x overrides everything else, but does not touch the cache.
|
||||
AC_DEFUN([AC_PATH_X],
|
||||
[dnl Document the X abnormal options inherited from history.
|
||||
m4_divert_once([HELP_BEGIN], [
|
||||
X features:
|
||||
--x-includes=DIR X include files are in DIR
|
||||
--x-libraries=DIR X library files are in DIR])dnl
|
||||
AC_MSG_CHECKING([for X])
|
||||
|
||||
AC_ARG_WITH(x, [ --with-x use the X Window System])
|
||||
# $have_x is `yes', `no', `disabled', or empty when we do not yet know.
|
||||
if test "x$with_x" = xno; then
|
||||
# The user explicitly disabled X.
|
||||
have_x=disabled
|
||||
else
|
||||
if test "x$x_includes" != xNONE && test "x$x_libraries" != xNONE; then
|
||||
# Both variables are already set.
|
||||
have_x=yes
|
||||
else
|
||||
_AC_PATH_X
|
||||
fi
|
||||
eval "$ac_cv_have_x"
|
||||
fi # $with_x != no
|
||||
|
||||
if test "$have_x" != yes; then
|
||||
AC_MSG_RESULT([$have_x])
|
||||
no_x=yes
|
||||
else
|
||||
# If each of the values was on the command line, it overrides each guess.
|
||||
test "x$x_includes" = xNONE && x_includes=$ac_x_includes
|
||||
test "x$x_libraries" = xNONE && x_libraries=$ac_x_libraries
|
||||
# Update the cache value to reflect the command line values.
|
||||
ac_cv_have_x="have_x=yes \
|
||||
ac_x_includes=$x_includes ac_x_libraries=$x_libraries"
|
||||
AC_MSG_RESULT([libraries $x_libraries, headers $x_includes])
|
||||
fi
|
||||
])# AC_PATH_X
|
||||
|
||||
|
||||
|
||||
# AC_PATH_XTRA
|
||||
# ------------
|
||||
# Find additional X libraries, magic flags, etc.
|
||||
AC_DEFUN([AC_PATH_XTRA],
|
||||
[AC_REQUIRE([AC_PATH_X])dnl
|
||||
if test "$no_x" = yes; then
|
||||
# Not all programs may use this symbol, but it does not hurt to define it.
|
||||
AC_DEFINE([X_DISPLAY_MISSING], 1,
|
||||
[Define if the X Window System is missing or not being used.])
|
||||
X_CFLAGS= X_PRE_LIBS= X_LIBS= X_EXTRA_LIBS=
|
||||
else
|
||||
if test -n "$x_includes"; then
|
||||
X_CFLAGS="$X_CFLAGS -I$x_includes"
|
||||
fi
|
||||
|
||||
# It would also be nice to do this for all -L options, not just this one.
|
||||
if test -n "$x_libraries"; then
|
||||
X_LIBS="$X_LIBS -L$x_libraries"
|
||||
dnl FIXME: banish uname from this macro!
|
||||
# For Solaris; some versions of Sun CC require a space after -R and
|
||||
# others require no space. Words are not sufficient . . . .
|
||||
case `(uname -sr) 2>/dev/null` in
|
||||
"SunOS 5"*)
|
||||
AC_MSG_CHECKING([whether -R must be followed by a space])
|
||||
ac_xsave_LIBS=$LIBS; LIBS="$LIBS -R$x_libraries"
|
||||
AC_LINK_IFELSE([AC_LANG_PROGRAM()], ac_R_nospace=yes, ac_R_nospace=no)
|
||||
if test $ac_R_nospace = yes; then
|
||||
AC_MSG_RESULT([no])
|
||||
X_LIBS="$X_LIBS -R$x_libraries"
|
||||
else
|
||||
LIBS="$ac_xsave_LIBS -R $x_libraries"
|
||||
AC_LINK_IFELSE([AC_LANG_PROGRAM()], ac_R_space=yes, ac_R_space=no)
|
||||
if test $ac_R_space = yes; then
|
||||
AC_MSG_RESULT([yes])
|
||||
X_LIBS="$X_LIBS -R $x_libraries"
|
||||
else
|
||||
AC_MSG_RESULT([neither works])
|
||||
fi
|
||||
fi
|
||||
LIBS=$ac_xsave_LIBS
|
||||
esac
|
||||
fi
|
||||
|
||||
# Check for system-dependent libraries X programs must link with.
|
||||
# Do this before checking for the system-independent R6 libraries
|
||||
# (-lICE), since we may need -lsocket or whatever for X linking.
|
||||
|
||||
if test "$ISC" = yes; then
|
||||
X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl_s -linet"
|
||||
else
|
||||
# Martyn Johnson says this is needed for Ultrix, if the X
|
||||
# libraries were built with DECnet support. And Karl Berry says
|
||||
# the Alpha needs dnet_stub (dnet does not exist).
|
||||
ac_xsave_LIBS="$LIBS"; LIBS="$LIBS $X_LIBS -lX11"
|
||||
AC_TRY_LINK_FUNC(XOpenDisplay, ,
|
||||
[AC_CHECK_LIB(dnet, dnet_ntoa, [X_EXTRA_LIBS="$X_EXTRA_LIBS -ldnet"])
|
||||
if test $ac_cv_lib_dnet_dnet_ntoa = no; then
|
||||
AC_CHECK_LIB(dnet_stub, dnet_ntoa,
|
||||
[X_EXTRA_LIBS="$X_EXTRA_LIBS -ldnet_stub"])
|
||||
fi])
|
||||
LIBS="$ac_xsave_LIBS"
|
||||
|
||||
# msh@cis.ufl.edu says -lnsl (and -lsocket) are needed for his 386/AT,
|
||||
# to get the SysV transport functions.
|
||||
# Chad R. Larson says the Pyramis MIS-ES running DC/OSx (SVR4)
|
||||
# needs -lnsl.
|
||||
# The nsl library prevents programs from opening the X display
|
||||
# on Irix 5.2, according to T.E. Dickey.
|
||||
# The functions gethostbyname, getservbyname, and inet_addr are
|
||||
# in -lbsd on LynxOS 3.0.1/i386, according to Lars Hecking.
|
||||
AC_CHECK_FUNC(gethostbyname)
|
||||
if test $ac_cv_func_gethostbyname = no; then
|
||||
AC_CHECK_LIB(nsl, gethostbyname, X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl")
|
||||
if test $ac_cv_lib_nsl_gethostbyname = no; then
|
||||
AC_CHECK_LIB(bsd, gethostbyname, X_EXTRA_LIBS="$X_EXTRA_LIBS -lbsd")
|
||||
fi
|
||||
fi
|
||||
|
||||
# lieder@skyler.mavd.honeywell.com says without -lsocket,
|
||||
# socket/setsockopt and other routines are undefined under SCO ODT
|
||||
# 2.0. But -lsocket is broken on IRIX 5.2 (and is not necessary
|
||||
# on later versions), says Simon Leinen: it contains gethostby*
|
||||
# variants that don't use the nameserver (or something). -lsocket
|
||||
# must be given before -lnsl if both are needed. We assume that
|
||||
# if connect needs -lnsl, so does gethostbyname.
|
||||
AC_CHECK_FUNC(connect)
|
||||
if test $ac_cv_func_connect = no; then
|
||||
AC_CHECK_LIB(socket, connect, X_EXTRA_LIBS="-lsocket $X_EXTRA_LIBS", ,
|
||||
$X_EXTRA_LIBS)
|
||||
fi
|
||||
|
||||
# Guillermo Gomez says -lposix is necessary on A/UX.
|
||||
AC_CHECK_FUNC(remove)
|
||||
if test $ac_cv_func_remove = no; then
|
||||
AC_CHECK_LIB(posix, remove, X_EXTRA_LIBS="$X_EXTRA_LIBS -lposix")
|
||||
fi
|
||||
|
||||
# BSDI BSD/OS 2.1 needs -lipc for XOpenDisplay.
|
||||
AC_CHECK_FUNC(shmat)
|
||||
if test $ac_cv_func_shmat = no; then
|
||||
AC_CHECK_LIB(ipc, shmat, X_EXTRA_LIBS="$X_EXTRA_LIBS -lipc")
|
||||
fi
|
||||
fi
|
||||
|
||||
# Check for libraries that X11R6 Xt/Xaw programs need.
|
||||
ac_save_LDFLAGS=$LDFLAGS
|
||||
test -n "$x_libraries" && LDFLAGS="$LDFLAGS -L$x_libraries"
|
||||
# SM needs ICE to (dynamically) link under SunOS 4.x (so we have to
|
||||
# check for ICE first), but we must link in the order -lSM -lICE or
|
||||
# we get undefined symbols. So assume we have SM if we have ICE.
|
||||
# These have to be linked with before -lX11, unlike the other
|
||||
# libraries we check for below, so use a different variable.
|
||||
# John Interrante, Karl Berry
|
||||
AC_CHECK_LIB(ICE, IceConnectionNumber,
|
||||
[X_PRE_LIBS="$X_PRE_LIBS -lSM -lICE"], , $X_EXTRA_LIBS)
|
||||
LDFLAGS=$ac_save_LDFLAGS
|
||||
|
||||
fi
|
||||
AC_SUBST(X_CFLAGS)dnl
|
||||
AC_SUBST(X_PRE_LIBS)dnl
|
||||
AC_SUBST(X_LIBS)dnl
|
||||
AC_SUBST(X_EXTRA_LIBS)dnl
|
||||
])# AC_PATH_XTRA
|
||||
502
lib/autoconf/programs.m4
Normal file
502
lib/autoconf/programs.m4
Normal file
@ -0,0 +1,502 @@
|
||||
# This file is part of Autoconf. -*- Autoconf -*-
|
||||
# Checking for programs.
|
||||
# Copyright 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000, 2001
|
||||
# Free Software Foundation, Inc.
|
||||
|
||||
# This program is free software; you can redistribute it and/or modify
|
||||
# it under the terms of the GNU General Public License as published by
|
||||
# the Free Software Foundation; either version 2, or (at your option)
|
||||
# any later version.
|
||||
#
|
||||
# This program is distributed in the hope that it will be useful,
|
||||
# but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||||
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||||
# GNU General Public License for more details.
|
||||
#
|
||||
# You should have received a copy of the GNU General Public License
|
||||
# along with this program; if not, write to the Free Software
|
||||
# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
|
||||
# 02111-1307, USA.
|
||||
|
||||
# As a special exception, the Free Software Foundation gives unlimited
|
||||
# permission to copy, distribute and modify the configure scripts that
|
||||
# are the output of Autoconf. You need not follow the terms of the GNU
|
||||
# General Public License when using or distributing such scripts, even
|
||||
# though portions of the text of Autoconf appear in them. The GNU
|
||||
# General Public License (GPL) does govern all other use of the material
|
||||
# that constitutes the Autoconf program.
|
||||
#
|
||||
# Certain portions of the Autoconf source text are designed to be copied
|
||||
# (in certain cases, depending on the input) into the output of
|
||||
# Autoconf. We call these the "data" portions. The rest of the Autoconf
|
||||
# source text consists of comments plus executable code that decides which
|
||||
# of the data portions to output in any given case. We call these
|
||||
# comments and executable code the "non-data" portions. Autoconf never
|
||||
# copies any of the non-data portions into its output.
|
||||
#
|
||||
# This special exception to the GPL applies to versions of Autoconf
|
||||
# released by the Free Software Foundation. When you make and
|
||||
# distribute a modified version of Autoconf, you may extend this special
|
||||
# exception to the GPL to apply to your modified version as well, *unless*
|
||||
# your modified version has the potential to copy into its output some
|
||||
# of the text that was the non-data portion of the version that you started
|
||||
# with. (In other words, unless your change moves or copies text from
|
||||
# the non-data portions to the data portions.) If your modification has
|
||||
# such potential, you must delete any notice of this special exception
|
||||
# to the GPL from your modified version.
|
||||
#
|
||||
# Written by David MacKenzie, with help from
|
||||
# Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
|
||||
# Roland McGrath, Noah Friedman, david d zuhn, and many others.
|
||||
|
||||
|
||||
## ----------------------------- ##
|
||||
## Generic checks for programs. ##
|
||||
## ----------------------------- ##
|
||||
|
||||
|
||||
# AC_SHELL_PATH_WALK([PATH = $PATH], BODY)
|
||||
# ----------------------------------------
|
||||
# Walk through PATH running BODY for each `ac_dir'.
|
||||
#
|
||||
# `$ac_dummy' forces splitting on constant user-supplied paths.
|
||||
# POSIX.2 word splitting is done only on the output of word
|
||||
# expansions, not every word. This closes a longstanding sh security
|
||||
# hole.
|
||||
m4_define([AC_SHELL_PATH_WALK],
|
||||
[ac_save_IFS=$IFS; IFS=$ac_path_separator
|
||||
ac_dummy="m4_default([$1], [$PATH])"
|
||||
for ac_dir in $ac_dummy; do
|
||||
IFS=$ac_save_IFS
|
||||
test -z "$ac_dir" && ac_dir=.
|
||||
$2
|
||||
done
|
||||
])
|
||||
|
||||
|
||||
# AC_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
|
||||
# [VALUE-IF-FOUND], [VALUE-IF-NOT-FOUND],
|
||||
# [PATH], [REJECT])
|
||||
# -----------------------------------------------------
|
||||
AC_DEFUN([AC_CHECK_PROG],
|
||||
[# Extract the first word of "$2", so it can be a program name with args.
|
||||
set dummy $2; ac_word=$[2]
|
||||
AC_MSG_CHECKING([for $ac_word])
|
||||
AC_CACHE_VAL(ac_cv_prog_$1,
|
||||
[if test -n "$$1"; then
|
||||
ac_cv_prog_$1="$$1" # Let the user override the test.
|
||||
else
|
||||
m4_ifvaln([$6],
|
||||
[ ac_prog_rejected=no])dnl
|
||||
AC_SHELL_PATH_WALK([$5],
|
||||
[AS_EXECUTABLE_P("$ac_dir/$ac_word") || continue
|
||||
m4_ifvaln([$6],
|
||||
[if test "$ac_dir/$ac_word" = "$6"; then
|
||||
ac_prog_rejected=yes
|
||||
continue
|
||||
fi])dnl
|
||||
ac_cv_prog_$1="$3"
|
||||
echo "$as_me:__oline__: found $ac_dir/$ac_word" >&AS_MESSAGE_LOG_FD
|
||||
break])
|
||||
m4_ifvaln([$6],
|
||||
[if test $ac_prog_rejected = yes; then
|
||||
# We found a bogon in the path, so make sure we never use it.
|
||||
set dummy $ac_cv_prog_$1
|
||||
shift
|
||||
if test $[@%:@] != 0; then
|
||||
# We chose a different compiler from the bogus one.
|
||||
# However, it has the same basename, so the bogon will be chosen
|
||||
# first if we set $1 to just the basename; use the full file name.
|
||||
shift
|
||||
set dummy "$ac_dir/$ac_word" ${1+"$[@]"}
|
||||
shift
|
||||
ac_cv_prog_$1="$[@]"
|
||||
m4_if([$2], [$4],
|
||||
[ else
|
||||
# Default is a loser.
|
||||
AC_MSG_ERROR([$1=$6 unacceptable, but no other $4 found in dnl
|
||||
m4_default([$5], [\$PATH])])
|
||||
])dnl
|
||||
fi
|
||||
fi])dnl
|
||||
dnl If no 4th arg is given, leave the cache variable unset,
|
||||
dnl so AC_CHECK_PROGS will keep looking.
|
||||
m4_ifvaln([$4],
|
||||
[ test -z "$ac_cv_prog_$1" && ac_cv_prog_$1="$4"])dnl
|
||||
fi])dnl
|
||||
$1=$ac_cv_prog_$1
|
||||
if test -n "$$1"; then
|
||||
AC_MSG_RESULT([$$1])
|
||||
else
|
||||
AC_MSG_RESULT([no])
|
||||
fi
|
||||
AC_SUBST($1)dnl
|
||||
])# AC_CHECK_PROG
|
||||
|
||||
|
||||
# AC_CHECK_PROGS(VARIABLE, PROGS-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND],
|
||||
# [PATH])
|
||||
# ------------------------------------------------------------------
|
||||
AC_DEFUN([AC_CHECK_PROGS],
|
||||
[for ac_prog in $2
|
||||
do
|
||||
AC_CHECK_PROG([$1], [$ac_prog], [$ac_prog], , [$4])
|
||||
test -n "$$1" && break
|
||||
done
|
||||
m4_ifvaln([$3], [test -n "$$1" || $1="$3"])])
|
||||
|
||||
|
||||
# AC_PATH_PROG(VARIABLE, PROG-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND], [PATH])
|
||||
# -----------------------------------------------------------------------
|
||||
AC_DEFUN([AC_PATH_PROG],
|
||||
[# Extract the first word of "$2", so it can be a program name with args.
|
||||
set dummy $2; ac_word=$[2]
|
||||
AC_MSG_CHECKING([for $ac_word])
|
||||
AC_CACHE_VAL([ac_cv_path_$1],
|
||||
[case $$1 in
|
||||
[[\\/]]* | ?:[[\\/]]*)
|
||||
ac_cv_path_$1="$$1" # Let the user override the test with a path.
|
||||
;;
|
||||
*)
|
||||
AC_SHELL_PATH_WALK([$4],
|
||||
[if AS_EXECUTABLE_P("$ac_dir/$ac_word"); then
|
||||
ac_cv_path_$1="$ac_dir/$ac_word"
|
||||
echo "$as_me:__oline__: found $ac_dir/$ac_word" >&AS_MESSAGE_LOG_FD
|
||||
break
|
||||
fi])
|
||||
dnl If no 3rd arg is given, leave the cache variable unset,
|
||||
dnl so AC_PATH_PROGS will keep looking.
|
||||
m4_ifvaln([$3],
|
||||
[ test -z "$ac_cv_path_$1" && ac_cv_path_$1="$3"])dnl
|
||||
;;
|
||||
esac])dnl
|
||||
AC_SUBST([$1], [$ac_cv_path_$1])
|
||||
if test -n "$$1"; then
|
||||
AC_MSG_RESULT([$$1])
|
||||
else
|
||||
AC_MSG_RESULT([no])
|
||||
fi
|
||||
])# AC_PATH_PROG
|
||||
|
||||
|
||||
# AC_PATH_PROGS(VARIABLE, PROGS-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND],
|
||||
# [PATH])
|
||||
# -----------------------------------------------------------------
|
||||
AC_DEFUN([AC_PATH_PROGS],
|
||||
[for ac_prog in $2
|
||||
do
|
||||
AC_PATH_PROG([$1], [$ac_prog], , [$4])
|
||||
test -n "$$1" && break
|
||||
done
|
||||
m4_ifvaln([$3], [test -n "$$1" || $1="$3"])dnl
|
||||
])
|
||||
|
||||
|
||||
|
||||
|
||||
## -------------------------- ##
|
||||
## Generic checks for tools. ##
|
||||
## -------------------------- ##
|
||||
|
||||
|
||||
# AC_CHECK_TOOL_PREFIX
|
||||
# --------------------
|
||||
AU_DEFUN([AC_CHECK_TOOL_PREFIX])
|
||||
|
||||
|
||||
# AC_PATH_TOOL(VARIABLE, PROG-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND], [PATH])
|
||||
# -----------------------------------------------------------------------
|
||||
# (Use different variables $1 and ac_pt_$1 so that cache vars don't conflict.)
|
||||
AC_DEFUN([AC_PATH_TOOL],
|
||||
[if test -n "$ac_tool_prefix"; then
|
||||
AC_PATH_PROG([$1], [${ac_tool_prefix}$2], , [$4])
|
||||
fi
|
||||
if test -z "$ac_cv_path_$1"; then
|
||||
ac_pt_$1=$$1
|
||||
AC_PATH_PROG([ac_pt_$1], [$2], [$3], [$4])
|
||||
$1=$ac_pt_$1
|
||||
else
|
||||
$1="$ac_cv_path_$1"
|
||||
fi
|
||||
])# AC_PATH_TOOL
|
||||
|
||||
|
||||
# AC_CHECK_TOOL(VARIABLE, PROG-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND], [PATH])
|
||||
# ------------------------------------------------------------------------
|
||||
# (Use different variables $1 and ac_ct_$1 so that cache vars don't conflict.)
|
||||
AC_DEFUN([AC_CHECK_TOOL],
|
||||
[if test -n "$ac_tool_prefix"; then
|
||||
AC_CHECK_PROG([$1], [${ac_tool_prefix}$2], [${ac_tool_prefix}$2], , [$4])
|
||||
fi
|
||||
if test -z "$ac_cv_prog_$1"; then
|
||||
ac_ct_$1=$$1
|
||||
AC_CHECK_PROG([ac_ct_$1], [$2], [$2], [$3], [$4])
|
||||
$1=$ac_ct_$1
|
||||
else
|
||||
$1="$ac_cv_prog_$1"
|
||||
fi
|
||||
])# AC_CHECK_TOOL
|
||||
|
||||
|
||||
# AC_CHECK_TOOLS(VARIABLE, PROGS-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND],
|
||||
# [PATH])
|
||||
# ------------------------------------------------------------------
|
||||
# Check for each tool in PROGS-TO-CHECK-FOR with the cross prefix. If
|
||||
# none can be found with a cross prefix, then use the first one that
|
||||
# was found without the cross prefix.
|
||||
AC_DEFUN([AC_CHECK_TOOLS],
|
||||
[if test -n "$ac_tool_prefix"; then
|
||||
for ac_prog in $2
|
||||
do
|
||||
AC_CHECK_PROG([$1],
|
||||
[$ac_tool_prefix$ac_prog], [$ac_tool_prefix$ac_prog],,
|
||||
[$4])
|
||||
test -n "$$1" && break
|
||||
done
|
||||
fi
|
||||
if test -z "$$1"; then
|
||||
ac_ct_$1=$$1
|
||||
AC_CHECK_PROGS([ac_ct_$1], [$2], [$3], [$4])
|
||||
$1=$ac_ct_$1
|
||||
fi
|
||||
])# AC_CHECK_TOOLS
|
||||
|
||||
|
||||
|
||||
## ---------------- ##
|
||||
## Specific tests. ##
|
||||
## ---------------- ##
|
||||
|
||||
# Please, keep this section sorted.
|
||||
# (But of course when keeping related things together).
|
||||
|
||||
# Check for mawk first since it's generally faster.
|
||||
AC_DEFUN([AC_PROG_AWK],
|
||||
[AC_CHECK_PROGS(AWK, mawk gawk nawk awk, )])
|
||||
|
||||
|
||||
# _AC_PROG_ECHO
|
||||
# -------------
|
||||
# Check whether to use -n, \c, or newline-tab to separate
|
||||
# checking messages from result messages.
|
||||
# Don't try to cache, since the results of this macro are needed to
|
||||
# display the checking message. In addition, caching something used once
|
||||
# has little interest.
|
||||
# Idea borrowed from dist 3.0. Use `*c*,', not `*c,' because if `\c'
|
||||
# failed there is also a new-line to match.
|
||||
m4_define([_AC_PROG_ECHO],
|
||||
[case `echo "testing\c"; echo 1,2,3`,`echo -n testing; echo 1,2,3` in
|
||||
*c*,-n*) ECHO_N= ECHO_C='
|
||||
' ECHO_T=' ' ;;
|
||||
*c*,* ) ECHO_N=-n ECHO_C= ECHO_T= ;;
|
||||
*) ECHO_N= ECHO_C='\c' ECHO_T= ;;
|
||||
esac
|
||||
AC_SUBST(ECHO_C)dnl
|
||||
AC_SUBST(ECHO_N)dnl
|
||||
AC_SUBST(ECHO_T)dnl
|
||||
])# _AC_PROG_ECHO
|
||||
|
||||
|
||||
# AC_PROG_INSTALL
|
||||
# ---------------
|
||||
AC_DEFUN([AC_PROG_INSTALL],
|
||||
[AC_REQUIRE([AC_CONFIG_AUX_DIR_DEFAULT])dnl
|
||||
# Find a good install program. We prefer a C program (faster),
|
||||
# so one script is as good as another. But avoid the broken or
|
||||
# incompatible versions:
|
||||
# SysV /etc/install, /usr/sbin/install
|
||||
# SunOS /usr/etc/install
|
||||
# IRIX /sbin/install
|
||||
# AIX /bin/install
|
||||
# AmigaOS /C/install, which installs bootblocks on floppy discs
|
||||
# AIX 4 /usr/bin/installbsd, which doesn't work without a -g flag
|
||||
# AFS /usr/afsws/bin/install, which mishandles nonexistent args
|
||||
# SVR4 /usr/ucb/install, which tries to use the nonexistent group "staff"
|
||||
# ./install, which can be erroneously created by make from ./install.sh.
|
||||
AC_MSG_CHECKING([for a BSD compatible install])
|
||||
if test -z "$INSTALL"; then
|
||||
AC_CACHE_VAL(ac_cv_path_install,
|
||||
[ ac_save_IFS=$IFS; IFS=$ac_path_separator
|
||||
for ac_dir in $PATH; do
|
||||
IFS=$ac_save_IFS
|
||||
# Account for people who put trailing slashes in PATH elements.
|
||||
case $ac_dir/ in
|
||||
/ | ./ | .// | /[cC]/* \
|
||||
| /etc/* | /usr/sbin/* | /usr/etc/* | /sbin/* | /usr/afsws/bin/* \
|
||||
| /usr/ucb/* ) ;;
|
||||
*)
|
||||
# OSF1 and SCO ODT 3.0 have their own names for install.
|
||||
# Don't use installbsd from OSF since it installs stuff as root
|
||||
# by default.
|
||||
for ac_prog in ginstall scoinst install; do
|
||||
if AS_EXECUTABLE_P(["$ac_dir/$ac_prog"]); then
|
||||
if test $ac_prog = install &&
|
||||
grep dspmsg "$ac_dir/$ac_prog" >/dev/null 2>&1; then
|
||||
# AIX install. It has an incompatible calling convention.
|
||||
:
|
||||
elif test $ac_prog = install &&
|
||||
grep pwplus "$ac_dir/$ac_prog" >/dev/null 2>&1; then
|
||||
# program-specific install script used by HP pwplus--don't use.
|
||||
:
|
||||
else
|
||||
ac_cv_path_install="$ac_dir/$ac_prog -c"
|
||||
break 2
|
||||
fi
|
||||
fi
|
||||
done
|
||||
;;
|
||||
esac
|
||||
done
|
||||
])dnl
|
||||
if test "${ac_cv_path_install+set}" = set; then
|
||||
INSTALL=$ac_cv_path_install
|
||||
else
|
||||
# As a last resort, use the slow shell script. We don't cache a
|
||||
# path for INSTALL within a source directory, because that will
|
||||
# break other packages using the cache if that directory is
|
||||
# removed, or if the path is relative.
|
||||
INSTALL=$ac_install_sh
|
||||
fi
|
||||
fi
|
||||
dnl We do special magic for INSTALL instead of AC_SUBST, to get
|
||||
dnl relative paths right.
|
||||
AC_MSG_RESULT([$INSTALL])
|
||||
|
||||
# Use test -z because SunOS4 sh mishandles braces in ${var-val}.
|
||||
# It thinks the first close brace ends the variable substitution.
|
||||
test -z "$INSTALL_PROGRAM" && INSTALL_PROGRAM='${INSTALL}'
|
||||
AC_SUBST(INSTALL_PROGRAM)dnl
|
||||
|
||||
test -z "$INSTALL_SCRIPT" && INSTALL_SCRIPT='${INSTALL}'
|
||||
AC_SUBST(INSTALL_SCRIPT)dnl
|
||||
|
||||
test -z "$INSTALL_DATA" && INSTALL_DATA='${INSTALL} -m 644'
|
||||
AC_SUBST(INSTALL_DATA)dnl
|
||||
])# AC_PROG_INSTALL
|
||||
|
||||
|
||||
# AC_PROG_LEX
|
||||
# -----------
|
||||
# Look for flex or lex. Set its associated library to LEXLIB.
|
||||
# Check if lex declares yytext as a char * by default, not a char[].
|
||||
AC_DEFUN_ONCE([AC_PROG_LEX],
|
||||
[AC_CHECK_PROGS(LEX, flex lex, :)
|
||||
if test -z "$LEXLIB"
|
||||
then
|
||||
AC_CHECK_LIB(fl, yywrap, LEXLIB="-lfl",
|
||||
[AC_CHECK_LIB(l, yywrap, LEXLIB="-ll")])
|
||||
fi
|
||||
AC_SUBST(LEXLIB)
|
||||
if test "x$LEX" != "x:"; then
|
||||
_AC_PROG_LEX_YYTEXT_DECL
|
||||
fi])
|
||||
|
||||
|
||||
# _AC_PROG_LEX_YYTEXT_DECL
|
||||
# ------------------------
|
||||
# Check if lex declares yytext as a char * by default, not a char[].
|
||||
m4_define([_AC_PROG_LEX_YYTEXT_DECL],
|
||||
[AC_CACHE_CHECK(lex output file root, ac_cv_prog_lex_root,
|
||||
[# The minimal lex program is just a single line: %%. But some broken lexes
|
||||
# (Solaris, I think it was) want two %% lines, so accommodate them.
|
||||
cat >conftest.l <<_ACEOF
|
||||
%%
|
||||
%%
|
||||
_ACEOF
|
||||
AC_TRY_COMMAND($LEX conftest.l)
|
||||
if test -f lex.yy.c; then
|
||||
ac_cv_prog_lex_root=lex.yy
|
||||
elif test -f lexyy.c; then
|
||||
ac_cv_prog_lex_root=lexyy
|
||||
else
|
||||
AC_MSG_ERROR([cannot find output from $LEX; giving up])
|
||||
fi])
|
||||
rm -f conftest.l
|
||||
AC_SUBST([LEX_OUTPUT_ROOT], [$ac_cv_prog_lex_root])dnl
|
||||
|
||||
AC_CACHE_CHECK(whether yytext is a pointer, ac_cv_prog_lex_yytext_pointer,
|
||||
[# POSIX says lex can declare yytext either as a pointer or an array; the
|
||||
# default is implementation-dependent. Figure out which it is, since
|
||||
# not all implementations provide the %pointer and %array declarations.
|
||||
ac_cv_prog_lex_yytext_pointer=no
|
||||
echo 'extern char *yytext;' >>$LEX_OUTPUT_ROOT.c
|
||||
ac_save_LIBS=$LIBS
|
||||
LIBS="$LIBS $LEXLIB"
|
||||
AC_LINK_IFELSE([`cat $LEX_OUTPUT_ROOT.c`], ac_cv_prog_lex_yytext_pointer=yes)
|
||||
LIBS=$ac_save_LIBS
|
||||
rm -f "${LEX_OUTPUT_ROOT}.c"
|
||||
])
|
||||
dnl
|
||||
if test $ac_cv_prog_lex_yytext_pointer = yes; then
|
||||
AC_DEFINE(YYTEXT_POINTER, 1,
|
||||
[Define if `lex' declares `yytext' as a `char *' by default,
|
||||
not a `char[]'.])
|
||||
fi
|
||||
])# _AC_PROG_LEX_YYTEXT_DECL
|
||||
|
||||
|
||||
# Require AC_PROG_LEX in case some people were just calling this macro.
|
||||
AU_DEFUN([AC_DECL_YYTEXT], [AC_PROG_LEX])
|
||||
|
||||
|
||||
# AC_PROG_LN_S
|
||||
# ------------
|
||||
AC_DEFUN([AC_PROG_LN_S],
|
||||
[AC_MSG_CHECKING([whether ln -s works])
|
||||
AC_SUBST([LN_S], [$as_ln_s])dnl
|
||||
if test "$LN_S" = "ln -s"; then
|
||||
AC_MSG_RESULT([yes])
|
||||
else
|
||||
AC_MSG_RESULT([no, using $LN_S])
|
||||
fi
|
||||
])# AC_PROG_LN_S
|
||||
|
||||
|
||||
# AC_PROG_MAKE_SET
|
||||
# ----------------
|
||||
# Define SET_MAKE to set ${MAKE} if make doesn't.
|
||||
AC_DEFUN([AC_PROG_MAKE_SET],
|
||||
[AC_MSG_CHECKING([whether ${MAKE-make} sets \${MAKE}])
|
||||
set dummy ${MAKE-make}; ac_make=`echo "$[2]" | sed 'y,./+-,__p_,'`
|
||||
AC_CACHE_VAL(ac_cv_prog_make_${ac_make}_set,
|
||||
[cat >conftest.make <<\_ACEOF
|
||||
all:
|
||||
@echo 'ac_maketemp="${MAKE}"'
|
||||
_ACEOF
|
||||
# GNU make sometimes prints "make[1]: Entering...", which would confuse us.
|
||||
eval `${MAKE-make} -f conftest.make 2>/dev/null | grep temp=`
|
||||
if test -n "$ac_maketemp"; then
|
||||
eval ac_cv_prog_make_${ac_make}_set=yes
|
||||
else
|
||||
eval ac_cv_prog_make_${ac_make}_set=no
|
||||
fi
|
||||
rm -f conftest.make])dnl
|
||||
if eval "test \"`echo '$ac_cv_prog_make_'${ac_make}_set`\" = yes"; then
|
||||
AC_MSG_RESULT([yes])
|
||||
SET_MAKE=
|
||||
else
|
||||
AC_MSG_RESULT([no])
|
||||
SET_MAKE="MAKE=${MAKE-make}"
|
||||
fi
|
||||
AC_SUBST([SET_MAKE])dnl
|
||||
])# AC_PROG_MAKE_SET
|
||||
|
||||
|
||||
# AC_PROG_RANLIB
|
||||
# --------------
|
||||
AC_DEFUN([AC_PROG_RANLIB],
|
||||
[AC_CHECK_TOOL(RANLIB, ranlib, :)])
|
||||
|
||||
|
||||
# AC_RSH
|
||||
# ------
|
||||
# I don't know what it used to do, but it no longer does.
|
||||
AU_DEFUN([AC_RSH],
|
||||
[AC_DIAGNOSE([obsolete], [$0: is no longer supported.
|
||||
Remove this warning when you adjust the code.])])
|
||||
|
||||
|
||||
# AC_PROG_YACC
|
||||
# ------------
|
||||
AC_DEFUN([AC_PROG_YACC],
|
||||
[AC_CHECK_PROGS(YACC, 'bison -y' byacc, yacc)])
|
||||
@ -1,5 +1,5 @@
|
||||
Makefile
|
||||
at-* atconfig experr expout stderr stdout
|
||||
at-* atlocal atconfig experr expout stderr stdout
|
||||
config.h config.hin
|
||||
config.log
|
||||
config.status
|
||||
|
||||
@ -14,10 +14,8 @@ AT_CHECK_MACRO([AC_PREFIX_DEFAULT])
|
||||
|
||||
# Obsolete macros.
|
||||
AT_CHECK_AU_MACRO([AC_CHECKING])
|
||||
AT_CHECK_AU_MACRO([AC_CHECK_TOOL_PREFIX])
|
||||
AT_CHECK_AU_MACRO([AC_COMPILE_CHECK])
|
||||
AT_CHECK_AU_MACRO([AC_ENABLE])
|
||||
AT_CHECK_AU_MACRO([AC_HAVE_LIBRARY])
|
||||
AT_CHECK_AU_MACRO([AC_OUTPUT_COMMANDS])
|
||||
AT_CHECK_AU_MACRO([AC_VALIDATE_CACHED_SYSTEM_TUPLE])
|
||||
AT_CHECK_AU_MACRO([AC_WITH])
|
||||
|
||||
9
tests/aclibs.at
Normal file
9
tests/aclibs.at
Normal file
@ -0,0 +1,9 @@
|
||||
# Generated by mktests.sh, do not edit by hand. -*- Autotest -*-
|
||||
# Copyright 2000, 2001 Free Software Foundation, Inc.
|
||||
|
||||
AT_BANNER([Testing autoconf/libs macros.])
|
||||
|
||||
# Modern macros.
|
||||
|
||||
# Obsolete macros.
|
||||
AT_CHECK_AU_MACRO([AC_HAVE_LIBRARY])
|
||||
18
tests/acprograms.at
Normal file
18
tests/acprograms.at
Normal file
@ -0,0 +1,18 @@
|
||||
# Generated by mktests.sh, do not edit by hand. -*- Autotest -*-
|
||||
# Copyright 2000, 2001 Free Software Foundation, Inc.
|
||||
|
||||
AT_BANNER([Testing autoconf/programs macros.])
|
||||
|
||||
# Modern macros.
|
||||
AT_CHECK_MACRO([AC_PROG_AWK])
|
||||
AT_CHECK_MACRO([AC_PROG_INSTALL])
|
||||
AT_CHECK_MACRO([AC_PROG_LEX])
|
||||
AT_CHECK_MACRO([AC_PROG_LN_S])
|
||||
AT_CHECK_MACRO([AC_PROG_MAKE_SET])
|
||||
AT_CHECK_MACRO([AC_PROG_RANLIB])
|
||||
AT_CHECK_MACRO([AC_PROG_YACC])
|
||||
|
||||
# Obsolete macros.
|
||||
AT_CHECK_AU_MACRO([AC_CHECK_TOOL_PREFIX])
|
||||
AT_CHECK_AU_MACRO([AC_DECL_YYTEXT])
|
||||
AT_CHECK_AU_MACRO([AC_RSH])
|
||||
@ -8,23 +8,14 @@ AT_CHECK_MACRO([AC_AIX])
|
||||
AT_CHECK_MACRO([AC_DECL_SYS_SIGLIST])
|
||||
AT_CHECK_MACRO([AC_ISC_POSIX])
|
||||
AT_CHECK_MACRO([AC_MINIX])
|
||||
AT_CHECK_MACRO([AC_PROG_AWK])
|
||||
AT_CHECK_MACRO([AC_PROG_INSTALL])
|
||||
AT_CHECK_MACRO([AC_PROG_LEX])
|
||||
AT_CHECK_MACRO([AC_PROG_LN_S])
|
||||
AT_CHECK_MACRO([AC_PROG_MAKE_SET])
|
||||
AT_CHECK_MACRO([AC_PROG_RANLIB])
|
||||
AT_CHECK_MACRO([AC_PROG_YACC])
|
||||
AT_CHECK_MACRO([AC_SYS_INTERPRETER])
|
||||
AT_CHECK_MACRO([AC_SYS_LARGEFILE])
|
||||
AT_CHECK_MACRO([AC_SYS_LONG_FILE_NAMES])
|
||||
|
||||
# Obsolete macros.
|
||||
AT_CHECK_AU_MACRO([AC_ARG_ARRAY])
|
||||
AT_CHECK_AU_MACRO([AC_DECL_YYTEXT])
|
||||
AT_CHECK_AU_MACRO([AC_DYNIX_SEQ])
|
||||
AT_CHECK_AU_MACRO([AC_HAVE_POUNDBANG])
|
||||
AT_CHECK_AU_MACRO([AC_IRIX_SUN])
|
||||
AT_CHECK_AU_MACRO([AC_RSH])
|
||||
AT_CHECK_AU_MACRO([AC_SCO_INTL])
|
||||
AT_CHECK_AU_MACRO([AC_XENIX_DIR])
|
||||
|
||||
Loading…
Reference in New Issue
Block a user